Jak rychle extrahovat všechny příjemce z více souborů zpráv aplikace Outlook (.msg)

Někteří uživatelé by chtěli rychle extrahovat všechny příjemce z více souborů zpráv aplikace Outlook uložených z e-mailů aplikace Outlook. Nyní, tato strost se na to podíváme, abychom sdíleli rychlý přístup.

Chcete-li extrahovat příjemce z jednoho souboru zpráv aplikace Outlook, otevřete jej dvojitým kliknutím a poté zkopírujte příjemce do otevřeného okna zprávy. Pokud však potřebujete vypořádat se s dávkou souborů zpráv aplikace Outlook, manuální metoda není dostatečně účinná. Můžete tedy hledat mnohem efektivnější způsob. Zde vám takový představíme. Čtěte dále a získáte jeho podrobnosti.

Extrahujte všechny příjemce z více souborů zpráv aplikace Outlook (.msg)

1. Pro jakotart, získejte přístup k editoru Outlook VBA podle „Jak spustit kód VBA ve vašem Outlooku".
2. Dále zkopírujte a vložte následující kód VBA do prázdného modulu.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Poté přesuňte kurzor v prvním podprogramu.
4. Poté klikněte na tlačítko „Spustit“ nebo stiskněte klávesu „F5“.
5. Poté v rozbalovacím dialogovém okně vyberte složku Windows, která obsahuje zdrojové soubory zpráv aplikace Outlook (.msg).
6. Po výběru klikněte na „OK“, aby makro pokračovalo v provozu.
7. Po dokončení makra se zobrazí zpráva se seznamem všech e-mailových adres všech extrahovaných příjemců, jak je znázorněno na následujícím snímku obrazovky.

Chraňte svá data Outlooku před nebezpečím

Data aplikace Outlook jsou sice náchylná k poškození. Proto je poměrně obtížný úkol chránit data aplikace Outlook. Vyžaduje, abyste vytrvali při pravidelném zálohování dat aplikace Outlook. Je-li to možné, je také obezřetné a doporučuje se připravit zkušený a profesionální Outlook Oprava PST nástroj, jako DataNumen Outlook Repair, takže můžete získat okamžitou a včasnou záchranu v případě poškození aplikace Outlook.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně zotavit se Sql Server a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com