Jak automaticky zvýrazňovat důležité e-maily, na které jste neodpověděli v Outlooku

Abyste nezapomněli odpovídat na důležité e-maily, můžete si přát, aby aplikace Outlook zobrazovala důležité e-maily, na které jste neodpověděli, v konkrétní barvě manifestu, aby je zvýraznila. Nyní vás tento článek naučí, jak jej získat.

Zmeškali jste někdy důležité e-maily a neodpověděli jste na ně včas? Pokud jste se s podobnými problémy setkali, možná budete doufat, že Outlook dokáže zvýraznit důležité e-maily, na které jste neodpověděli. Nyní vás v následujícím textu provedeme, jak toho dosáhnout pomocí VBA. Pokud neznáte VBA, podívejte se prosím na můj předchozí článek – “Jak spustit kód VBA ve vašem Outlooku“Mezitím.

Automaticky zvýraznit důležité e-maily, na které jste neodpověděli

1. Na úplném začátku otevřete editor VBA pomocí „Alt + F11“ v aplikaci Outlook.
2. Poté v novém okně zkopírujte níže uvedený kód do projektu „ThisOutlookSession“.

Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

3. Poté přesuňte kurzor do makra „Application_Startup“ a stiskněte klávesu „F5“.
4. Později toto okno zavřete.
5. Následně podle níže uvedených kroků vytvořte pravidlo podmíněného formátování pro položky ve složce Doručená pošta.

• Nejprve se přepněte do složky „Doručená pošta“.
• Poté přejděte na kartu „Zobrazit“ a klikněte na „Zobrazit nastavení“.
• V novém dialogovém okně klikněte na tlačítko „Podmíněné formátování“.
• V dalším dialogovém okně „Podmíněné formátování“ klikněte na „Přidat“ a zadejte název nového pravidla, například „Důležité e-maily bez odpovědi“.
• Později klikněte na tlačítko „Font…“ a nastavte styl a barvu písma ve vyskakovacím dialogovém okně „Font“.
• Po zadání písma klikněte na „Podmínka…“ v dialogovém okně „Podmíněné formátování“.
• Následně na obrazovce „Filtr“ na kartě „Upřesnit“ přidejte dva filtry.

1. „Důležitost“ > „rovná se“ > „Vysoká“
2. „Odpovězeno“ > „je (přesně)“ > „Ne“

• Nakonec klikněte na řadu „OK“, abyste toto pravidlo formátování uložili.

6. Po návratu do složky Doručená pošta budou všechny důležité e-maily, na které jste neodpověděli, zvýrazněny konkrétním písmem a barvou.

Nenechte se unášet ochranou dat aplikace Outlook

Nesčetné množství uživatelů si stále myslí, že k poškození dat nikdy nedojde. Ve skutečnosti jsou takové myšlenky zcela mylné a riskantní. Většinou může malá chyba snadno vést ke ztrátě dat. Pokud například omylem kliknete na škodlivý odkaz v neznámých e-mailech, váš soubor Outlooku může být napaden virem a dokonce i poškozen. Proto byste měli být při ochraně dat neustále opatrní, například pravidelně zálohovat PST a připravovat si účinný nástroj pro opravu, jako je DataNumen Outlook Repair, které mohou opravit Outlook problémy za okamžik.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně obnovit mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com