3 rychlé způsoby, jak odstranit prázdné řádky a sloupce v tabulce Word

V tomto příspěvku vám vysvětlíme 3 rychlé způsoby, jak odstranit prázdné řádky a sloupce v tabulce ve Wordu.

Tabulky jsou pro dokument zásadní, zejména při uchovávání různých typů dat. Dlouhý stůl někdy může přesáhnout stránku a přesáhnout několik. Jakmile bude tabulka zdlouhavá a komplikovaná, můžete ji zjednodušit pomocí opatření. Můžete například odstranit nepotřebné prázdné řádky a sloupce.

Můžete použít 3 metody.

Metoda 1: Ruční odstranění prázdných řádků a sloupců

1. Nejprve vyberte prázdný řádek nebo sloupec.
2. Poté klikněte pravým tlačítkem a získejte kontextové menu. V nabídce odpovídajícím způsobem vyberte možnost „Odstranit řádky“ nebo „Odstranit sloupce“.

Bohužel nemůžete vybrat několik po sobě jdoucích řádků nebo sloupců a odstranit je společně tímto způsobem. Pro tento požadavek si můžete přečíst náš předchozí článek: 5 rychlých metod pro dávkové odstranění více řádků nebo sloupců v tabulce Word

Metoda 2: Dávkové odstranění všech prázdných řádků a sloupců v tabulce

Metoda 1 má své omezení. Takže vám nabídneme způsob dávkového odebrání řádků a sloupců v tabulce pomocí kódů VBA.

1. Pro začátek umístěte kurzor do cílové tabulky.
2. Za druhé spusťte editor VBA stisknutím kláves „Alt + F11“.
3. V editoru nejprve klikněte na projekt „Normální“.
4. Poté klikněte na kartu „Vložit“ na liště nabídek.
5. V rozbalovací nabídce zvolte „Modul“.
6. Dvojitým kliknutím otevřete modul a vložte tam následující kódy:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Nakonec klikněte na tlačítko „Spustit“ na liště nabídek nebo stiskněte „F5“.

Během několika sekund budou odstraněny všechny prázdné řádky a sloupce v této tabulce.

Metoda 3: Dávkové odstranění všech prázdných řádků a sloupců ve všech tabulkách v dokumentu

1. Nejprve opakujte kroky v metodě 2 pro instalaci a spuštění makra.
2. Pouze tentokrát nahraďte toto makro následujícím:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Obnovte nefunkční dokument

V dnešní době existuje více než jen jeden způsob, jak obnovit ztracená data. Například zálohování je vždy vaší nejvyšší prioritou. Pokud to neuspokojí vaši potřebu získat nejnovější informace zpět, můžete zkusit... oprava dokumentu nástroj.

Úvod autora:

Vera Chen je expertka na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně xlsx oprava a pdf opravy softwarových produktů. Pro více informací navštivte www.datanumen.com