2 rychlé způsoby, jak najít nebo odstranit věty obsahující konkrétní text ve vašem slově

V tomto článku vám nabídneme 2 rychlé způsoby, jak vyhledat nebo odstranit věty obsahující konkrétní text ve vašem Wordu.

Je známo všem, že můžeme pomocí funkce „Najít a nahradit“ v aplikaci Word snadno najít všechny výskyty konkrétních slov. Pak nebudeme mít problém je zvýraznit, nahradit nebo odstranit. Jak vidíte, target je slovo nebo fráze. Dnes vám však s potěšením sdělíme, jakým způsobem lze makro najít nebo odstranit věty obsahující určitý text.

Metoda 1: Vyhledání nebo odstranění vět obsahujících konkrétní text

1. Nejprve stisknutím kombinace kláves „Alt + F11“ spusťte editor VBA v aplikaci Word.
2. Poté vytvořte nový modul kliknutím na „Normální“.
3. Poté klikněte na „Vložit“ a zvolte „Modul“, abyste získali nový.
4. A modul otevřete dvojitým kliknutím.
5. Nyní vložte následující kódy:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Dále klikněte na „Spustit“.
7. K dispozici bude vstupní pole s výzvou k zadání textu. Stačí napsat běžný text, který obsahují všechny věty. Klikněte na „OK“.
8. Poté uvidíte větu obsahující vybraný text a zobrazí se výzva se zprávou. Kliknutím na „Ano“ větu odstraníte, kliknutím na „Ne“ ji ponecháte.
9. Po potvrzení je na výběr další věta s určeným textem. A je zde také potvrzovací rámeček. Makro konkrétně vás provede procházením celého dokumentu a nalezením tarzískejte věty a pokaždé požádejte o potvrzení.

Metoda 2: Vyhledání nebo odstranění vět obsahujících jakýkoli text v seznamu

S makrem v metodě 1 můžete vyhledávat pouze jedno slovo nebo frázi najednou. Určitě můžete makro spustit opakovaně a vyhledat více instancí slov nebo frází. Abychom vyhověli potřebě vícenásobného vyhledávání, poskytneme vám další makro.

1. Nejprve vložte vše tarzískávat texty v novém dokumentu. Ujistěte se, že každý text zabírá jeden odstavec bez koncové mezery. Zavřete a uložte dokument.
2. Dále nainstalujte a spusťte makro s přesnými kroky v metodě 1.
3. Poté nahraďte makro tímto:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Nyní se otevře okno „Procházet“. Vyberte právě uložený dokument a klikněte na „Otevřít“.
5. Následující postup je stejný jako v metodě 1.

Přístup k řešení poškozených dokumentů

Ztráta cenných dat je naprosto zničující. Může to dokonce nechat vaše podnikání v sázce. Abyste se vyhnuli takové frustraci, musíte se zmocnit a Oprava aplikace Word nástroj co nejdříve. Takový nástroj vám pomůže vyhrát bitvu s poškozením dokumentů.

Úvod autora:

Vera Chen je expertka na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně opravit Excel a pdf opravy softwarových produktů. Pro více informací navštivte www.datanumen.com