2 rychlé způsoby, jak extrahovat sekce z dokumentu Word

V tomto článku vám nabídneme 2 rychlé a snadné způsoby, jak extrahovat oddíly z dokumentu Word do jiného nebo více.

Extrahovat obsah z jednoho dokumentu do druhého se stává poměrně často. A v našem předchozím článku jsme diskutovali o tom, jak extrahovat stránky z dokumentu. Podrobné informace najdete v tomto článku: 2 rychlé způsoby, jak extrahovat jednotlivé stránky z dokumentu Word

Dnes vám ukážeme, jak extrahovat podle sekce.    

Metoda 1: Extrakce aktuální sekce do nového dokumentu

1. Nejprve umístěte kurzor do cílové sekce.
2. Poté stiskněte „Alt + F11“ pro vyvolání editoru VBA ve Wordu.
3. Poté v levém sloupci klikněte na „Normální“.
4. Na liště nabídek klikněte na „Vložit“.
5. Poté v rozbalovací nabídce vyberte možnost „Modul“.
6. Dvojitým kliknutím otevřete nový modul a vložte tam následující kódy:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Dále klikněte na „Spustit“ na řádku nabídek nebo stiskněte „F5“.
8. Poté se objeví okno „Procházet“. Vyberte místo pro uložení nového dokumentu a klikněte na „OK“.
9. A do pole „Název souboru“ zadejte název nového souboru a klikněte na „OK“.

Nyní jste sekci extrahovali do nového dokumentu.

Metoda 2: Extrahujte každou část dokumentu na jednotlivé nové

Tímto způsobem můžete dávkově zpracovat všechny sekce v dokumentu. Samozřejmě budeme potřebovat také makro.

1. Nejprve otevřete cílový dokument.
2. Poté postupujte podle kroků v metodě 1 k instalaci a spuštění makra.
3. Pouze tentokrát nahraďte toto makro tímto:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Přesto v okně „Procházet“ vyberte cestu úložiště a klikněte na „OK“.

Opravte dráždivé chyby slov

Je běžné, že při jeho používání narazíte na některé chyby Wordu. Může to být nepříjemné, musíme si na to dát čas obnovit slovo co nejdříve. Protože čím déle to zpozdíme, tím závažnější může být ztráta dat. Proto se doporučuje předem sehnat nástroj pro opravu.

Úvod autora:

Vera Chen je expertka na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně poškozené xls a pdf opravy softwarových produktů. Pro více informací navštivte www.datanumen.com