2 rychlé způsoby, jak extrahovat jednotlivé stránky z dokumentu Word

V dnešním příspěvku se s vámi chceme podělit o 2 rychlé způsoby, jak extrahovat jednotlivé stránky z dokumentu Word.

Někdy v dokumentu Word může každá stránka obsahovat zcela nezávislý obsah, například tabulku. A pravděpodobně budete muset poslat různé tabulky různým lidem. Poté budete muset každou tabulku, která je každou stránkou, uložit jako samostatný soubor.

První myšlenkou, která nás napadne, by mělo být klasické kopírování a vkládání. Něco, co zahrnuje výběr, může být někdy nepříjemné, protože přetažením a výběrem lze snadno dosáhnout konce bez výběru vůbec. Z tohoto důvodu vám doporučujeme provést 2 rychlé metody pomocí makra.

Metoda 1: Extrahujte aktuální stránku a uložte ji jako nový dokument

1. V první řadě umístěte kurzor na stránku, kterou chcete extrahovat.
2. Klikněte na kartu „Vývojář“ a poté na „Visual Basic“ pro vyvolání editoru VBA. Pokud není aktivován „Developer“, jednoduše stiskněte „Alt + F11“.
3. Zadruhé klikněte na projekt „Normální“.
4. Dále klikněte na záložku „Vložit“ a zvolte „Modul“.
5. Poklepáním na nový modul otevřete oblast úprav.
6. Pak tam vložte následující kódy:

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. Nakonec klikněte na tlačítko „Spustit“.

Nyní budou 2 vstupní pole. Do prvního vstupního pole zadejte cestu, kam chcete uložit nový dokument. A zadejte název nového dokumentu na druhém.

Metoda 2: Extrahujte každou stránku a uložte ji jako nový dokument

Následující makro vám umožní extrahovat každou jednotlivou stránku dokumentu.

1. Nejprve stisknutím „Ctrl + Home“ přejděte na samý začátek dokumentu.
2. Poté postupujte podle stejných kroků v metodě 1 k instalaci a spuštění makra.
3. Tentokrát nahraďte makro tímto:

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Řešení problémů se slovy

Vždycky se vyskytnou různé problémy s Wordem. Jde o to naučit se je správně řešit. Nejdoporučnějším způsobem je samozřejmě pořídit si sofistikovaný nástroj. Obnova slov nástroj. Měli byste využít každou minutu k obnovení dat, než bude příliš pozdě.

Úvod autora:

Vera Chen je expertka na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně zkorumpovaný xlsx a pdf opravy softwarových produktů. Pro více informací navštivte www.datanumen.com