如何快速將Outlook電子郵件導出為圖像文件

一些用戶希望將Outlook電子郵件導出為圖像文件，例如jpg文件。 因此，在本文中，我們將向您介紹如何通過Outlook VBA代碼獲得它。

您必須學習各種將電子郵件導出為文本文件，Word文檔等的技巧。 然後，如何將電子郵件導出為JPG文件之類的圖片呢？ 顯然，Outlook沒有此功能。 但是，此後，我們將與您快速分享信息。

快速將Outlook電子郵件導出為圖像文件

1. 首先，啟動 Outlook 應用程式。
2. 然後，在Outlook主窗口中，根據以下文章訪問“ VBA編輯器”：如何在Outlook中運行VBA代碼“。
3. 接下來，啟用「MS Word 物件庫」和「MS PowerPoint 透過引用文章「物件庫」——如何在 VBA 中新增物件庫引用“。
4. 接下來，將以下VBA代碼複製並粘貼到空白模塊中。

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. 之後，您需要將宏添加到快速訪問工具欄。
6. 隨後，您可以關閉VBA編輯器。
7. 以後，選擇一封電子郵件，然後單擊快速訪問工具欄中的宏按鈕。
8. 宏完成後，您可以轉到預定義的本地文件夾以從此電子郵件中找到導出的圖像文件。

從損壞的文件中檢索Outlook數據

如果您的 Outlook 檔案嚴重損壞，您可能會非常沮喪。在這種情況下，您需要從受損檔案中提取 Outlook 資料。有些使用者會嘗試使用收件匣修復工具。然而，大多數情況下，這些工具都無法發揮作用。因此，您最好準備一個強大可靠的工具。 PST修復 工具，例如 DataNumen Outlook Repair。 它可以掃描損壞的文件並獲取最大的數據，而不必大驚小怪。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 mdf修復 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM