如何通過 VBA 快速將文件夾結構從一個 Outlook PST 文件複製到另一個

Outlook解決方案 2025 年 9 月 29 日
立即分享：

如果您想將文件夾結構從一個 Outlook PST 文件複製到另一個，可以使用本文介紹的方法，它將教您如何使用 VBA 一次性獲取它。

也許，為了更好地管理您的電子郵件，您在主 Outlook 文件中創建了多個自定義文件夾。 因此，在創建新的 Outlook PST 文件時，您可能希望應用相同的文件夾結構。 事實上，在我之前的文章中——“只需兩個步驟即可在新 Outlook 檔案中保留目前資料夾層次結構”，你可以學習一個傳統的方法，就是利用“歸檔”功能來實現。 儘管如此，實際上還是有點乏味。 相比之下，使用VBA代碼來獲取會快很多。 因此，下面我們將詳細的步驟和代碼告訴您。

快速將文件夾結構從一個 Outlook PST 文件複製到另一個

將文件夾結構從一個 Outlook PST 文件複製到另一個

  1. 首先，啟動 Outlook 程式。
  2. 然後在Outlook窗口中，按“ Alt + F11”鍵按鈕。
  3. 接下來您將進入 Outlook VBA 編輯器窗口。
  4. 隨後，將以下 VBA 代碼複製並粘貼到新模塊中。
Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

VBA 代碼 - 將文件夾結構從一個 Outlook PST 文件複製到另一個

  1. 之後，將宏安全級別更改為低。
  2. 隨後返回 VBA 編輯器窗口並按“F5”鍵運行宏。
  3. 最後，宏工作完成後，您將收到一條消息，提示“已完成！”。消息提示已完成
  4. 此時，您可以進入郵件導航窗格。 您將看到一個新的 Outlook 數據文件，其文件夾結構與源 PST 文件相同，如下圖所示：複製文件夾結構

應對令人沮喪的 PST 問題

由於 Outlook PST 很容易出錯，因此許多人一定在 Outlook 中遇到過各種問題。 面對這些問題，您可以先使用Outlook收件箱修復工具來嘗試一下。 如果失敗，您可以應用更強大的第三方工具，例如 DataNumen Outlook Repair， 哪個行 修復Outlook PST 錯誤輕而易舉。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 SQL Server 固定 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM

立即分享：

評論被關閉。