如何直接在 Outlook 中打開超鏈接而不是新的瀏覽器窗口

Outlook解決方案 2025 年 9 月 29 日

當您單擊 Outlook 電子郵件中的超鏈接時，該鏈接將在您的默認 Internet 瀏覽器中打開。但實際上您也可以使用本文介紹的方法直接在 Outlook 中打開超鏈接。

您一定知道，當您單擊 Outlook 電子郵件中的超鏈接時，該鏈接的網頁將通過您的默認 Internet 瀏覽器打開。然而，有許多用戶希望直接在 Outlook 中打開超鏈接。在 Outlook 的早期版本中，有一個可見且明顯的 Web 工具。但現在，這個功能被隱藏了。即便如此，實際上 Outlook 仍然可以作為 Web 瀏覽器使用。您可以應用以下使用 Outlook VBA 的方法來快速實現它。

直接在 Outlook 中打開超鏈接，而不是在新瀏覽器窗口中打開

首先，啟動Outlook應用程序。
然後按“ Alt + F11”鍵按鈕。
隨後，您將成功進入Outlook VBA編輯器窗口。
接下來，將以下 VBA 代碼複製並粘貼到未使用的模塊中。

Public Sub OpenHyperlinkswithinOutlook()
    Dim objMail As Outlook.MailItem
    Dim objWordDocument As Word.Document
    Dim objHyperlinks As Word.Hyperlinks
    Dim i As Long
    Dim objHyperlink As Word.Hyperlink
    Dim strHyperlinkList As String
    Dim strNumber As String
    Dim strURL As String
    Dim objExplorer As Explorer
    Dim objWebBrowser As Object
    Dim nAlert As Integer
 
    On Error Resume Next
    Select Case TypeName(Outlook.Application.ActiveWindow)
           Case "Inspector"
                Set objMail = ActiveInspector.CurrentItem
           Case "Explorer"
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select

    Set objWordDocument = objMail.GetInspector.WordEditor
    Set objHyperlinks = objWordDocument.Hyperlinks
 
    If objHyperlinks.Count < 1 Then
       nAlert = MsgBox("There is no hyperlink in this email!", vbExclamation)
 
       'Get the URL of the only hyperlink
    ElseIf objHyperlinks.Count = 1 Then
       Set objHyperlink = objWordDocument.Hyperlinks.Item(1)
       strURL = objHyperlink.Address
 
       'Select which hyperlink to open
    ElseIf objHyperlinks.Count > 1 Then
       For i = 1 To objHyperlinks.Count
           strHyperlinkList = strHyperlinkList & i & ": " & objHyperlinks.Item(i).Address & vbCrLf
       Next i
 
       For i = 1 To objHyperlinks.Count
           strNumber = InputBox("You have " & objHyperlinks.Count & " hyperlinks in this email as follows. " & vbCrLf & vbCrLf & "Please enter the number to select which one to be opened within your Outlook (format: 1)." & vbCrLf & vbCrLf & strHyperlinkList, "Select Hyperlink")
           Set objHyperlink = objWordDocument.Hyperlinks.Item(strNumber)
           strURL = objHyperlink.Address
           Exit For
       Next i
    End If
 
    'Open the selected hyperlink
    Set objExplorer = Application.ActiveExplorer
    Set objWebBrowser = objExplorer.CommandBars.FindControl(, 1740)

    objWebBrowser.Text = strURL
    objWebBrowser.Execute
End Sub