如何通過 VBA 和 UserForm 有效地向 Outlook 電子郵件添加註釋

Outlook解決方案 2025 年 9 月 29 日

有時，您可能希望在 Outlook 中為您的電子郵件編輯或添加註釋。本文將向您介紹實現該功能的有效方法。

來自“在Outlook郵件中插入註釋的4種簡單方法”，您可以學習通過 Outlook 原生功能在郵件中插入備註，例如使用自定義標誌、在主題或正文中鍵入備註，或將現有備註項目附加到此電子郵件。然而，所有這些都只是解決方法。在這裡，我們將教你一個更有效的方法。通過它，您將能夠在電子郵件中添加備註並隨意編輯或刪除現有備註。

向 Outlook 電子郵件添加備註

首先，在 Outlook 中按“Alt + F11”訪問 VBA 編輯器。
然後，單擊“插入”>“用戶窗體”。
接下來，在新的用戶窗體中，創建一個如下圖所示的文本框。
然後，將文本框的“名稱”更改為“txtNotes”，如截圖所示。
之後，在窗體中創建兩個命令按鈕。
然後，選擇“命令按鈕 1”。將其“名稱”更改為“btnOK”並將其“標題”更改為“確定”。
之後，將“CommandVutton 2”的“Name”更改為“btnCancel”，將“Caption”更改為“Cancel”。
接下來，選擇整個用戶窗體並將其“名稱”修改為“frmAddNote”，將“標題”修改為“輸入您的筆記”。
隨後，右鍵單擊“fromAddNote”並選擇“查看代碼”。
在新屏幕中，將以下代碼複製到其中。

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objNote = Application.CreateItem(olNoteItem)
 
    objNote.Body = strNote
    objNote.Save
    objMail.Attachments.Add objNote
    objMail.Save
    objNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

稍後，將下面的VBA代碼放入未使用的模塊中。

Sub AddNote()
    frmAddNote.Show
End Sub

最後，前往“文件”>“選項”>“自定義功能區”將此宏添加到功能區。
現在，你可以試一試。選擇一封電子郵件，然後單擊功能區中新的“添加註釋”按鈕。
在彈出的對話框中，您可以輸入您的筆記，然後單擊“確定”。
隨即，新便箋將添加到所選電子郵件中。

編輯或刪除 Outlook 電子郵件的現有備註

有時，您可能想要編輯或刪除電子郵件中的任何現有筆記。您可以按照以下步驟操作。

首先，創建另一個用戶表單並將其命名為“frmEditNote”並將其標題修改為“Edit your note”。
然後，在表單中插入一個新的文本框並將其“名稱”更改為“txtNotes”。
接下來，添加兩個命令按鈕——“確定”和“取消”。
之後，右鍵單擊“frmEditNote”並選擇“查看代碼”。
在“frmEditNote”的新代碼頁中，放入以下代碼。

Private Sub UserForm_Initialize()
    Dim objAttachNote As Outlook.Attachment
    Dim objTempNote As Outlook.NoteItem

    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    Set objMail = objAttachNote.Parent
 
    If Right(objAttachNote.FileName, 3) = "msg" Then
       strTempFolder = Environ("Temp")
       strFilePath = strTempFolder & "\" & objAttachNote.FileName
       objAttachNote.SaveAsFile strFilePath
    End If
 
    Set objTempNote = Session.OpenSharedItem(strFilePath)
    txtNotes.Text = objTempNote.Body

    objTempNote.Close olDiscard
End Sub

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objAttachNote As Outlook.Attachment
    Dim objNewNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objNewNote = Application.CreateItem(olNoteItem)
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    objAttachNote.Delete

    objNewNote.Body = strNote
    objNewNote.Save
    objMail.Attachments.Add objNewNote
    objMail.Save
    objNewNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

之後，打開一個模塊並將 VBA 代碼複製到其中。

Sub EditNote()
    frmEditNote.Show
End Sub

Sub DeleteNotes()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim objMail As Outlook.MailItem
 
    Set objSelectedAttachments = Application.ActiveExplorer.AttachmentSelection
 
    For Each objAttachment In objSelectedAttachments
        If Right(objAttachment.FileName, 3) = "msg" Then
           objAttachment.Delete
        End If
    Next
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    objMail.Save
End Sub