如何在Outlook中批量刪除所有已讀回執

Outlook解決方案 2025 年 9 月 29 日
立即分享：

為了確認收件者已閱讀您的郵件，您可以在撰寫郵件時要求已讀回執。這樣一來，您的信箱可能會被大量的已讀回執塞滿。本文將教您如何大量永久刪除這些已讀回執。

看完文章“如何在Outlook中批量刪除所有收貨”，您可以考慮批量刪除所有已讀回執的方法。 實際上，兩種收據之間的明顯區別在於它們的主題。 交貨收據的主題中包含“已交貨”，但已讀的收據則包含“已讀”。 因此，您可以使用相同的方式批量刪除所有已讀回執。 在下文中，我們將詳細教您具體的步驟。

批量刪除所有已讀回執

  1. 首先，啟動 Outlook。
  2. 然後，根據“通過“ Alt + F11”轉到Outlook VBA編輯器如何在Outlook中運行VBA代碼“。
  3. 接下來，在新窗口中，打開一個空模塊，並將以下代碼放入其中。
Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

VBA代碼-批量刪除所有已讀回執

  1. 之後，單擊進入第一個子例程。
  2. 最後，按“ F5”鍵按鈕。
  3. 宏將立即刪除您的Outlook中的所有已讀回執。
  4. 完成後，您將得到有關結果的提示，如下面的屏幕截圖所示。結果提示
  5. 目前，您可以檢查您的郵件文件夾。 所有已讀回執均已消失。閱讀收據已經過去了

捍衛Outlook數據

儘管Outlook文件很容易受到損壞，但我們可以採取措施來保護它。 例如，我們應該將Outlook文件保持較小尺寸，保護它免受惡意因素的侵害，並定期對其進行備份。 最後但並非最不重要的一點是，您最好準備一個強大的外部PST修復工具，例如 DataNumen Outlook Repair。 它將對維修產生重大影響 腐敗的Outlook 文件。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 sql修復 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM

立即分享：

評論被關閉。