通過VBA快速將多個Word文檔合併為2種方法

在本文中，我們很高興與您分享兩種通過VBA快速將多個Word文檔合併為一個文檔的方法。

在Word中，有默認的內置功能來幫助用戶將多個文檔合併或合併為一個。 詳細信息在本文中進行了解釋： 如何將多個Word文檔合併和合併為一個

使用這種方法，您必須單擊兩次，並且下一個文檔的內容總是緊接在前一個文檔之後。 因此，我們希望為您提供更快的方法。

方法1：將選定的文檔合併到一個

1. 第一和前ost，創建一個新的空白文檔。
2. 通過按“ Alt + F11”在Word中觸發VBA編輯器。
3. 接下來單擊“正常”。
4. 然後點擊“插入”。
5. 然後選擇“模塊”。
6. 雙擊新模塊以打開編輯空間。
7. 在其中粘貼以下宏：

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. 接下來單擊“運行”或單擊“ F5”。
9. 現在，在“瀏覽”窗口中，按“ Ctrl”選擇多個文件，然後單擊“確定”。
10. 然後，所選文件中的所有內容將與新文檔一起拼湊在一起，每個文檔的文本tar在新頁面上顯示

請注意：

如前所述，該宏將每個文檔的文本放在新頁面上。 但是，如果您需要它們一個接一個，則可以更改宏中的某些代碼行。 只需找到“如果nEachSelectedFile <nTotalFiles然後”行，則將其刪除以及接下來的六行。

方法2：將一個文件夾中的所有文檔合併到一個

如果您有一個要合併的文件文件夾，則此宏可以正常工作。

1. 到tar關閉，按照方法1所述安裝並運行宏。
2. 然後用這個替換宏：

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. 單擊“運行”運行宏。
4. 接下來，您會看到“瀏覽”窗口打開。 選擇用於存儲所有文檔的文件夾。 然後點擊“確定”。

同樣，每個文檔的文本tar在新頁面上。 為了使它們彼此緊貼在一起，找到並刪除代碼行“ .InsertBreak Type：= wdPageBreak”。

正確保護您的Word文檔

保護您的Word文檔的最好方法之一就是定期備份它們。 有了備份，您將永遠不必擔心數據丟失。 此外，建議您使用 維修文件 如果有任何損壞。

作者簡介：

陳薇薇（Vera Chen）是 DataNumen，Inc.是數據恢復技術的全球領導者，包括 損壞的Excel 以及 pdf 維修軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM