同時在一個Word文檔中查找多個項目的2種快速方法

Word解決方案 2025 年 9 月 28 日

在這篇文章中，我們將重點放在兩種快速尋找 Word 文件中多個項目的方法。

任何熟悉Word的人都必須非常了解“查找和替換”選項。當查找文本是連續的字符串時，它可以很好地工作。但是，不幸的是，當我們想同時搜索多個單獨的單詞時，它變得很複雜。而且，一口氣刪除一份文檔中的單詞或短語列表的需求非常強烈。例如，如果您是編輯者，則可能有幾個單詞永遠不會出現在任何文檔中。如果是這樣，您將需要變通辦法來標記某些特定單詞的出現。

這裡有2種解決方案：

方法1：將單詞導入到排除字典

在Word中的排除詞典中添加一堆單詞或短語，然後在匹配的單詞下方會出現一條紅色波浪線，以將其標記出來。

本文中將單詞添加到排除字典的詳細步驟：單詞拼寫和語法檢查器的4個有用技巧

方法2：使用Word宏

首先，將所有要搜尋的詞語放在一個文件中。每個詞語或短語應佔一個段落。我們稱之為「清單文檔」。儲存文檔。
其次，單擊“開發人員”選項卡。
然後單擊“ Visual Basic”以打開VBA編輯器。另一種方法是按“ Alt + F11”。
接下來，單擊“普通”，然後單擊“插入”選項卡。
然後在菜單上選擇“模塊”。
雙擊新模塊以彈出編輯區域，然後在其中粘貼以下宏：

Sub FindMultiItemsInDoc()
  Dim objListDoc As Document
  Dim objTargetDoc As Document
  Dim objParaRange As Range, objFoundRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String

  strFileName = InputBox("Enter the full name of the list document here:")
 
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
      With Selection
        .HomeKey Unit:=wdStory
 
        '  Find target items.
        With Selection.Find
          .ClearFormatting
          .Text = objParaRange
          .MatchWholeWord = True
          .MatchCase = False
          .Execute
        End With
 
        '  Highlight the found items.
        Do While .Find.Found
          Set objFoundRange = Selection.Range
          objFoundRange.HighlightColorIndex = wdBrightGreen
          .Collapse wdCollapseEnd
          .Find.Execute
        Loop
      End With
  Next objParagraph
End Sub