2種快速方法可將方括號批量添加到Word文檔中的註釋編號

Word解決方案 2025 年 9 月 28 日

在今天的文章中，我們很高興向您展示兩種快速批量在 Word 文件中為註釋編號添加方括號的方法。

每當起草長文件時，我們都可能會插入腳註和尾註。我們知道，微粒編號格式有多種選擇。但是，沒有帶方括號的內置數字樣式。在接下來的文章中，我們將討論解決該問題的兩種解決方案。

方法1：利用“查找和替換”功能

首先，按一下目標文件中的「開始」標籤。
然後單擊“編輯”組中的“替換”命令以打開“查找和替換”對話框。
現在，如果要使用腳註，請在“查找內容”文本框中輸入“ ^ f”。
在“替換為”文本框中輸入“ [^＆]”。
接下來單擊“全部替換”。
接下來，您會看到所有腳註數字都放在方括號中。單擊“確定”關閉消息框。

此外，要在尾註中添加方括號，只需在“查找內容”文本框中將“ ^ f”替換為“ ^ e”。

方法2：運行Word宏

首先，在 Word 中按下「Alt+F11」鍵啟動 VBA 編輯器。
接下來，單擊“普通”，然後單擊“插入”選項卡。
在下拉菜單上，選擇“模塊”。
然後雙擊新插入的模塊以打開右側的編輯區域。
並在下面粘貼以下宏：

Sub AddBracketForFootnoteAndEndnote()
  Application.ScreenUpdating = False
 
  Dim objRange As Range
 
  With ActiveDocument

    '  add bracket for footnotes. 
    If ActiveDocument.Footnotes.Count > 0 Then
      Call UpdateFootnoteRange(.Range)
      For Each objRange In .StoryRanges
        If objRange.StoryType = wdFootnotesStory Then
          Call UpdateFootnoteRange(objRange): Exit For
        End If
      Next
      MsgBox ("All footnotes have been added brackets.")
    Else
      MsgBox ("There is no footnote in this document")
    End If

    '  add bracket for footnotes. 
    If ActiveDocument.Endnotes.Count > 0 Then
      Call UpdateEndnoteRange(.Range)
      For Each objRange In .StoryRanges
        If objRange.StoryType = wdEndnotesStory Then
          Call UpdateEndnoteRange(objRange): Exit For
        End If
      Next
      MsgBox ("All endnotes have been added brackets.")
    Else
      MsgBox ("There is no endnote in this document")
    End If
  End With
 
  Application.ScreenUpdating = True
End Sub

Sub UpdateFootnoteRange(objRange As Range)
  With objRange.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "^f"
    .Replacement.Text = "[^&]"
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchByte = True
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute Replace:=wdReplaceAll
  End With
End Sub

Sub UpdateEndnoteRange(objRange As Range)
  With objRange.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "^e"
    .Replacement.Text = "[^&]"
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchByte = True
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute Replace:=wdReplaceAll
  End With
End Sub