Cách nhanh chóng loại trừ người nhận “CC” gốc khi sử dụng “Trả lời tất cả” trong Outlook

giải pháp triển vọng Tháng Chín 29, 2025

Khi sử dụng “Trả lời tất cả”, email phản hồi cũng sẽ bao gồm những người nhận “CC” của email gốc trong trường “CC”. Tuy nhiên, nếu bạn muốn loại trừ loại người nhận này, bạn có thể sử dụng phương pháp được giới thiệu trong bài viết này.

Đôi khi, bạn muốn trả lời email cho người gửi ban đầu và người nhận “Tới”. Trong trường hợp này, bạn chắc chắn sẽ nghĩ đến việc sử dụng tùy chọn “Trả lời tất cả”. Tuy nhiên, bằng cách này, nếu thư gốc cũng có người nhận “CC”, email “Trả lời tất cả” sẽ tự động sao chép người nhận “CC” vào trường “CC”. Nếu không muốn trả lời họ, bạn phải gỡ bỏ chúng theo cách thủ công, điều này hơi rắc rối. Bây giờ, trong phần tiếp theo, chúng tôi sẽ hướng dẫn bạn cách để Outlook tự động thực hiện việc đó theo nhu cầu của bạn.

Nhanh chóng loại trừ người nhận “CC” gốc khi sử dụng “Trả lời tất cả”

Trước tiên, hãy mở Outlook.
Sau đó, truy cập trình soạn thảo VBA bằng cách đọc bài viết trước – “Cách chạy mã VBA trong Outlook của bạn".
Tiếp theo, sao chép mã VBA sau vào dự án “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

Tiếp theo, hãy khởi động lại Outlook để kích hoạt dự án mới này.
Kể từ đó, mỗi khi bạn nhấn nút “Trả lời tất cả”, bạn sẽ nhận được lời nhắc, như minh họa trong hình ảnh sau đây, hỏi xem bạn có muốn loại trừ những người nhận CC ban đầu hay không.
Nếu bạn chọn “Có”, Outlook sẽ tự động xóa người nhận trong trường “CC”.

Luôn chuẩn bị tốt cho thiệt hại trong Outlook

Như chúng ta đã biết, không ai có thể đảm bảo 100% rằng mình hoàn toàn miễn nhiễm với các lỗi xảy ra với Outlook. Do đó, điều cần thiết là tất cả người dùng Outlook thường xuyên phải thực hiện nhiều biện pháp phòng ngừa. Trước hết, một trong những điều quan trọng nhất là phải sao lưu dữ liệu Outlook một cách thường xuyên và cập nhật. Sau đó, cần phải học cách sử dụng công cụ sửa chữa hộp thư đến. Cuối cùng nhưng không kém phần quan trọng, việc có một người có kinh nghiệm hỗ trợ là điều khôn ngoan và được khuyến khích. sửa chữa Outlook công cụ trong vùng lân cận, chẳng hạn như DataNumen Outlook Repair.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm phục hồi mdf và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm