Cách tự động sử dụng các màu phông chữ khác nhau để trả lời và chuyển tiếp email với Outlook VBA

giải pháp triển vọng Tháng Chín 29, 2025

Theo mặc định, bạn không thể để Outlook tự động sử dụng các màu phông chữ khác nhau để trả lời và chuyển tiếp email. Do đó, nếu bạn có yêu cầu như vậy, bạn có thể đọc post để học cách tiếp cận thông minh.

Outlook chỉ cho phép bạn chỉ định phông chữ được sử dụng cho cả email trả lời và chuyển tiếp. Bạn có thể vào “Tệp” > “Tùy chọn”. Sau đó, trong “Tùy chọn Outlook”, chuyển sang tab “Thư” và nhấp vào nút “Văn phòng phẩm và Phông chữ…”. Trong cửa sổ tiếp theo, bạn có thể thấy nút “Phông chữ” trong “Trả lời hoặc chuyển tiếp tin nhắn”. Nhấp vào nó, sau đó bạn có thể đặt màu phông chữ cụ thể để trả lời và chuyển tiếp email.

Tuy nhiên, nhiều người dùng hy vọng sử dụng các màu phông chữ khác nhau để trả lời hoặc chuyển tiếp email. Mặc dù Outlook không cung cấp bất kỳ tính năng trực tiếp nào cho việc này, nhưng nó vẫn có thể được thực hiện bằng mã VBA. Bây giờ, hãy đọc tiếp để lấy một đoạn mã VBA như vậy.

Tự động sử dụng các màu phông chữ khác nhau để trả lời và chuyển tiếp email

Đối với nhưtart, khởi chạy ứng dụng Outlook.
Sau đó, kích hoạt trình soạn thảo VBA với tham chiếu đến “Cách chạy mã VBA trong Outlook của bạn".
Tiếp theo, theo “Cách thêm một đối tượng Library Tham khảo trong VBA“, hãy thêm tham chiếu đến “MS Word Object Library ”.
Sau đó, sao chép đoạn mã sau vào dự án “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

Sau đó, restart Outlook để kích hoạt macro này.
Cuối cùng, bạn có thể thử.

Chọn hoặc mở một email.
Sau đó, nhấp vào nút "Trả lời". Khi trả lời email, bạn có thể nhập một số từ trong nội dung. Màu chữ phải là màu hồng.
Hoặc nhấp vào nút "Trả lời tất cả". Trong thư "trả lời tất cả" mới, hãy nhập các từ trong nội dung. Màu phông chữ chắc chắn là màu xanh lá cây.
Tương tự, nhấp vào nút "Chuyển tiếp". Trong thư chuyển tiếp, các từ mới sẽ được hiển thị bằng màu xanh lam.

Sử dụng phần mềm đáng tin cậy

Trong trường hợp của Tham nhũng, most người dùng có xu hướng sử dụng phần mềm khôi phục Outlook. Có rất nhiều chương trình như vậy có sẵn trên thị trường. Và một số trong số họ thậm chí còn miễn phí. Tuy nhiên, bạn nên cẩn thận với những thứ từ các nguồn không xác định vì chúng có thể làm cho trường hợp hiện tại ngày càng tồi tệ hơn. Bạn nên nhờ sự trợ giúp của một công cụ đáng tin cậy và có kinh nghiệm, như DataNumen Outlook Repair.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm sql bị hỏng và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm