2 cách nhanh chóng để xuất danh sách tất cả các email Outlook được gắn cờ sang Excel

Nếu bạn muốn xuất danh sách tất cả các email được gắn cờ từ hộp thư Outlook sang Excel, bạn có thể sử dụng một trong 2 phương pháp được chia sẻ trong bài viết này.

Ví dụ: để xử lý tất cả các email được gắn cờ kịp thời hơn hoặc chia sẻ chúng với người khác, bạn có thể hy vọng xuất chúng sang trang tính Excel. Ở đây chúng tôi sẽ giới thiệu 2 cách tiếp cận để nhận ra nó. Cái trước sử dụng tính năng “Nhập và Xuất” tiêu chuẩn sau khi tìm thấy các email được gắn cờ. Thành thật mà nói, nó là một chút tẻ nhạt. Vì vậy, trong phần sau, chúng tôi sẽ hướng dẫn bạn cách áp dụng VBA thuận tiện hơn.

Phương pháp 1: Xuất tất cả các email được gắn cờ tìm thấy theo cách thủ công

1. Trước hết, nhấp vào hộp tìm kiếm phía trên danh sách thư.
2. Sau đó, nhấp vào “Tất cả các mục thư” trong nhóm “Phạm vi” trên tab “Tìm kiếm”.
3. Tiếp theo, nhấp vào nút “Đã gắn cờ” trong nhóm “Xác định”.
4. Sau khi tất cả các email được gắn cờ hiển thị trong danh sách, hãy chọn một thư và nhấn “Ctrl + A” để chọn tất cả chúng.
5. Sau đó, nhấn tổ hợp phím “Ctrl + Shift + V”.
6. Trong hộp thoại mới, tạo một thư mục mới trong tệp Outlook.
7. Sau đó, chọn thư mục mới tạo và nhấp vào “OK”, thao tác này sẽ chuyển tất cả các email được gắn cờ tìm thấy sang thư mục mới.
8. Sau đó, nhấp vào “Tệp” > “Mở” > “Nhập”,
9. Trong hộp thoại bật lên, hãy chọn “Xuất ra tệp” > “Tiếp theo” > “Microsoft Excel 97-2003” > “Tiếp theo”.
10. Trong màn hình mới, chọn đúng thư mục và nhấn “Next”.
11. Sau đó, hãy làm theo hướng dẫn để hoàn thành “Xuất”.
12. Bạn sẽ nhận được một tệp Excel mới, được hiển thị như ảnh chụp màn hình sau.

Phương pháp 2: Xuất danh sách tất cả các email được gắn cờ qua VBA

1. Trong Outlook, nhấn “Alt + F11” để kích hoạt trình soạn thảo VBA.
2. Sau đó, bật “Đối tượng MS Excel” theo “Cách thêm tham chiếu thư viện đối tượng trong VBA".
3. Tiếp theo, sao chép mã VBA bên dưới vào một mô-đun.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Cuối cùng, đặt con trỏ vào chương trình con “ExportAllFlaggedEmailsToExcel” và nhấn nút phím “F5”.
5. Sau đó, chọn một tệp Outlook trong hộp thoại mới.
6. Khi bạn nhận được lời nhắc “Đã hoàn thành”, bạn cũng sẽ nhận được một tệp Excel mới, giống như hình ảnh bên dưới.

Bảo vệ Outlook của bạn khỏi tham nhũng

Outlook dễ bị lỗi và hư hỏng, do đó việc bảo vệ dữ liệu Outlook của chúng ta là một nhiệm vụ rất khó khăn. Không nghi ngờ gì nữa, cách hiệu quả và thiết thực nhất là sao lưu dữ liệu Outlook thường xuyên. Bên cạnh đó, chúng ta cũng cần có một công cụ sửa lỗi Outlook mạnh mẽ và đáng tin cậy, chẳng hạn như... DataNumen Outlook Repair. Nó sẽ có ích nếu công cụ sửa chữa hộp thư đến không có tác dụng.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm sửa chữa SQL Server và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm