Paano Mag-export ng Maraming Mga Email sa Outlook sa Isang Word Document sa pamamagitan ng VBA

Kung nais mong i-batch ang pag-export ng maraming mga email ng Outlook sa isang solong dokumento ng salita, maaari mong gamitin ang VBA code na ipinapakita sa artikulong ito. Matutulungan ka nitong magawa ang gawaing ito sa loob ng ilang segundo.

Naipakilala ko na kung paano i-convert ang isang email sa Outlook sa isang dokumento ng Word sa aking nakaraang artikulo - “2 Mga Mabisang Pamamaraan upang Mag-convert ng isang Outlook Email sa isang dokumento ng Word". Gayunpaman, kapwa ang 2 nangangahulugang nabanggit sa post ay walang magawa sa kaso kung saan nais mong mag-export ng maraming mga email sa isang dokumento ng Word. Kaya't, dito ka namin magtuturo sa ibang paraan. Ngayon, basahin ito upang makuha ito nang detalyado.

I-export ang Batch ng Maramihang Mga Outlook ng Email sa Isang Word Document

1. Kay start sa, ilunsad ang iyong programa sa Outlook.
2. Pagkatapos, pagkatapos ipasok ang pangunahing window ng Outlook, kailangan mong pindutin ang mga pindutan ng "Alt + F11".
3. Susunod makakakuha ka ng pag-access sa Outlook VBA editor, kung saan dapat mong buksan ang isang blangkong module.
4. Kasunod, kopyahin ang VBA code sa ibaba sa binuksan na window ng module.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Pagkatapos nito, mas mahusay kang idagdag ang bagong proyekto ng VBA sa Quick Access Toolbar o laso.
6. Sa huli, maaari mong subukan.

• Sa unang lugar, pumili ng maraming mga email ng Outlook.
• Pagkatapos hanapin at mag-click sa bagong idinagdag na pindutan ng macro.
• Matapos ma-prompt ka ng "Kumpleto", maaari kang mag-browse sa paunang natukoy na lokal na folder upang makahanap ng isang bagong dokumento ng Word.
• Buksan ang dokumentong ito, kung saan makikita mo ang lahat ng napiling mga email na na-export.

Panatilihing Malapit ang isang Makapangyarihang Pag-recover ng Tool

Anuman ang maraming mga pag-andar, ang Outlook ay hindi pa rin mai-immune mula sa mga error. Kung nasanay ka na iwanang nag-iisa ang mga error, sa mga ito ay magkakasama, ang pag-crash ng Outlook ay siguradong magaganap. Sa puntong iyon, mahalaga na muling umulit sa isang makapangyarihang at epektibo na tool sa pagbawi, tulad ng DataNumen Outlook Repair. Bihasa ito sa Ayusin ang PST. Hangga't kasama nito, hindi mo na kailangang mag-alala pa tungkol sa pagkawala ng data ng pananaw.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang nasira mdf at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa