Paano Mabilis na I-export ang Mga Istatistika ng Pagboto mula sa isang Outlook Email sa isang Excel Worksheet

Kung nagpadala ka ng isang email na may mga pindutan sa pagboto, pagkatapos maipadala sa iyo ng mga tatanggap ang kanilang mga tugon, baka gusto mong bilangin at i-export ang mga istatistika ng pagboto sa isang worksheet ng Excel. Kaya, sa p na itoost, tuturuan namin kayo kung paano ito makamit nang mabilis.

Napakalakas ng Outlook na nag-aalok din ng tampok na "Pagboto". Ang aking nakaraang artikulo na "Kasanayang Paggamit ng MS Outlook para sa Pagboto”Ay nagturo kung paano ito magagamit nang mabisa. Gayundin, most ng oras, pagkatapos ng pagboto, maaari kang magpatuloy sa pag-export ng mga istatistika ng pagboto sa isang worksheet ng Excel para sa ilang mga kadahilanan, tulad ng nais na mai-print ang mga istatistika. Ngunit hindi ito sinusuportahan ng Outlook bilang default. Kaya, sa mga sumusunod, tuturuan ka namin kung paano mapagtanto ito tulad ng isang tapon.

I-export ang Mga Istatistika ng Pagboto sa isang Email sa isang Excel Worksheet

1. Sa simula pa lamang, ilunsad ang iyong aplikasyon sa Outlook.
2. Pagkatapos ay dapat mong pindutin ang mga pindutan ng "Alt + F11" sa mga pangunahing window ng Outlook.
3. Susunod sa window na "Microsoft Visual Basic for Applications", dapat mong paganahin ang "Microsoft Excel Object Library ”. I-click ang "Mga Tool"> "Sanggunian". Pagkatapos sa popup dialog box, markahan ang checkbox sa harap ng “Microsoft Excel Object Library ”at huli na pindutin ang“ OK ”.
4. Pagkatapos nito, maaari kang magpasok ng isang bagong module o magbukas ng hindi ginagamit na isa.
5. Kasunod, kopyahin at i-paste ang mga sumusunod na VBA code sa modyul na ito.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Pagkatapos nito, para sa maginhawang pag-access, mas mahusay mong idagdag ang bagong macro sa Quick Access Toolbar.
6. Sa paglaon, maaari kang magkaroon ng isang pagsubok.

• Una, pumili ng isang mapagkukunang email na naglalaman ng mga pindutan sa pagboto.
• Pagkatapos i-click ang pindutan ng macro sa Quick Access Toolbar.
• Matapos ang pagtakbo ng macro na ito, maaari kang mag-browse sa paunang natukoy na lokal na folder, kung saan makikita mo ang isang bagong workbook ng Excel.
• Buksan ang workbook ng Excel na ito. Ngayon makikita mo ang mga istatistika ng pagboto, ipinakita bilang imahe sa ibaba:

Walang Maaring Umiwas nang Masidhi sa Mga Error sa Outlook

Kahit na ang Outlook ay pinagkalooban ng iba't ibang mga kakayahan, walang ganoong tampok upang matulungan kaming maiwasan ang mga error sa Outlook. Ang lahat ng uri ng mga kadahilanan ay maaaring maging sanhi ng mga error sa Outlook. Halimbawa, kung madalas kang lumabas nang hindi wasto sa Outlook, malamang na maghirap ka Korapsyon sa PST. Sa ganitong senaryo, wala kang pagpipilian kundi ang gumamit ng ilang mga potent na tool upang iligtas ang iyong PST file, tulad ng DataNumen Outlook Repair. Kumita ito ng maraming mga kudos dahil sa mataas na rate ng pagbawi nito.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang tiwaling mdf at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa