2 Paraan para Mabilis na Magpadala ng Mga Napiling Cell sa isang Excel Worksheet bilang Outlook Email

Kung minsan, maaaring gusto mong mabilis na ipasok ang mga napiling cell sa isang Excel worksheet sa isang Outlook email at ipadala ang email na ito. Ang artikulong ito ay titingnan ang nais na mag-alok sa iyo ng 2 pamamaraan.

Ang aking nakaraang artikulo na "2 Mabilis na Paraan upang Magpadala ng isang Excel Worksheet bilang isang Outlook Email” ay nagturo sa iyo kung paano magpadala ng isang buong Excel worksheet bilang isang email. Gayunpaman, kung minsan, nais mo lamang ipadala ang mga napiling cell sa isang worksheet bilang isang email. Bilang tugon sa pangangailangang ito, dito namin ilalantad sa iyo ang 2 pamamaraan. Maaari mong piliin ang alinman ayon sa iyong kagustuhan.

Paraan 1: Kopyahin ang Mga Napiling Cell sa Manu-manong Email

1. Para magsimula, buksan ang source Excel file at i-access ang tamang Excel worksheet.
2. Pagkatapos ay piliin ang mga cell na gusto mong ipadala bilang isang Outlook email.
3. Susunod na pindutin ang "Ctrl + C" key shortcut upang kopyahin ang mga napiling cell.
4. Pagkatapos nito, ilunsad ang iyong Outlook application.
5. Kasunod nito, mag-click sa "Bagong Email" na buton sa "Home" ribbon upang lumikha ng bagong Outlook email.
6. Sa ibang pagkakataon sa bagong window ng Mensahe, mag-click sa seksyon ng katawan ng mensahe.
7. At pagkatapos ay pindutin ang "Ctrl + V" key buttons upang i-paste ang dati nang kinopya na mga napiling Excel cell.
8. Panghuli, maaari mong isulat ang email gaya ng dati at i-click ang "Ipadala" na buton upang ipadala ito.

Paraan 2: Ipadala ang Mga Napiling Cell bilang Email sa pamamagitan ng VBA

1. Sa pinakadulo simula, buksan ang source Excel workbook.
2. Pagkatapos ay pindutin ang "Alt + F11" key buttons para ma-access ang Excel VBA editor.
3. Sa bagong window, i-click ang “Insert” > “Module” para magpasok ng bagong module.
4. Susunod, dapat paganahin ang Microsoft Outlook Object. I-click ang "Tools" > "References". Sa popup dialog box, hanapin at lagyan ng tsek ang "Microsoft Outlook Object Library".
5. Kasunod, kopyahin ang sumusunod na VBA code sa modyul na ito.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Sa paglaon, maaari kang magkaroon ng isang pagsubok.

• Una, piliin ang mga partikular na cell gaya ng dati.
• Pagkatapos ay bumalik sa bagong macro at pindutin ang F5 key upang ma-trigger ito.
• Sabay-sabay, lalabas ang isang bagong email sa Outlook, kung saan makikita mo na ang mga napiling cell ay naipasok sa katawan ng email, tulad ng sumusunod na screenshot:

Ang PST File ay Parehong Vulnerable gaya ng Excel File

Gaya ng alam natin, ang Excel file at Word document ay madaling masira. Sa totoo lang, totoo rin ito para sa PST file, na naglalaman ng lahat ng item sa iyong Outlook mailbox. Kaya, isang mahirap na gawain ang pag-secure ng iyong PST data. Isa sa mga pinakamabisang hakbang ay ang regular na pag-backup ng file. Dagdag pa rito, upang makapagbigay ng agarang pagsagip, mas makabubuting maghanda ka ng isang bihasang tool, tulad ng DataNumen Outlook Repair, na may kakayahang bawiin ang Outlook data nang hindi pinagpapawisan.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang ayusin ang mdf at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa