Så här tar du snabbt bort dubbletter av Outlook-objekt i en mapp via VBA

Om du vill ta bort dubbletter i Outlook kan det vara ganska besvärligt att söka och ta bort dem en efter en. Det här inlägget lär dig hur du snabbt gör det med Outlook VBA.

I min tidigare artikel - “Hur man snabbt hittar och tar bort duplicerade e-postmeddelanden i Outlook”, Kan du lära dig ett trick för att hitta och ta bort dubbla e-postmeddelanden, som först sorterar e-postmeddelandena efter ämne, sedan efter mottagen tid och sedan efter bilagor för att ta reda på dubbletterna och slutligen markera de dubbletterna och tryck på” Radera ”-tangenten. Även om den här metoden är till synes lite mer praktisk, men den är mycket besvärligare jämfört med att använda Outlook VBA. Med följande VBA-koder kan du snabbt ta bort duplicerade objekt helt enkelt med ett klick, oavsett e-post, uppgifter, kontakter eller möten. Läs vidare för att få koder i detalj.

Ta bort dubbletter av Outlook-objekt i en mapp

1. Till att börja med, starta ditt Outlook-program.
2. Tryck sedan på “Alt + F11” -knapparna.
3. I det efterföljande VBA-redigeringsfönstret dubbelklickar du för att öppna en modul som används eller infogar direkt en ny modul med “Insert”> “Module”.
4. Nästa kopiera och klistra in följande VBA-koder i modulen.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Därefter signerar du detta makro digitalt och ändrar din säkerhetsnivå för Outlook-makro till låg.
6. Senare kan du köra det här nya VBA-projektet. Klicka direkt på ikonen "Kör" i verktygsfältet.
7. Därefter måste du välja en mapp där du vill ta bort dubbletter.
8. Slutligen raderas dubbletterna i den valda mappen på en gång.

Skydda sårbara PST-data

På grund av det faktum att PST-filen är mottaglig för korruption, bör du därför spendera mycket på att skydda din PST-fil. Du bör till exempel förhindra att Outlook stängs felaktigt. Dessutom måste du förbereda en robust Outlook-fix verktyg, såsom DataNumen Outlook Repair som kommer att kunna rädda din PST i tid.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive återhämta SQL Server och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com