Hur man snabbt exporterar den totala tid som används på Outlook-möten i varje färgkategori

Om du vill skapa en rapport om den totala tiden du spenderar på mötena i varje färgkategori kan du använda metoden som introduceras i den här artikeln. Det kan hjälpa dig att uppnå detta på kort tid utan att behöva räkna manuellt.

Många användare är vana vid att logga de flesta av sina aktiviteter i Outlook-kalendern. För att enklare hantera och differentiera dem tilldelar de kategorier till var och en av dem. I det här fallet vill vissa användare generera en rapport som visar den totala tiden som spenderats på kalenderposterna i varje färgkategori. Det är utan tvekan besvärligt att räkna och mata in manuellt. Därför delar vi här ett sätt som kan utföra denna uppgift med ett enkelt klick.

Exportera den totala tiden som spenderats på mötena i varje färgkategori

1. För det första, starta din Outlook-applikation.
2. Sedan, när du har angett Outlook-fönstret, kan du trycka på tangenterna ”Alt + F11”.
3. Därefter får du tillgång till “Microsoft Visual Basic for Applications” -fönstret.
4. Därefter måste du aktivera "Microsoft Excel Object Library". Du kan klicka på "Verktyg" > "Referens" för att göra det.
5. Sedan borde du hitta och öppna en modul som inte används.
6. Därefter måste du kopiera följande VBA-kod till den här modulen.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Slutligen kan du utlösa detta makro, oavsett genom att klicka på "Kör" -ikonen i verktygsfältet eller genom att trycka på "F5" -tangenten.
8. Sedan kommer du att krävas att du väljer en specifik kalender.
9. När du har valt och tryckt på “OK” fortsätter makrot att köra. När det är klart kommer det att finnas en ny Excel-fil som visas i bakgrunden.
10. Du kan komma åt den. Det kommer att se ut som följande skärmdump:

Håll utkik efter potentiella hot kring Outlook

Outlook-användare bör se upp alla potentiella risker, inklusive okända e-postbilagor, inbäddade länkar och mänskliga fel. Annars kan din Outlook skadas när som helst. Det är också nödvändigt att göra säkerhetskopior av Outlook regelbundet och behålla ett specialiserat reparationsverktyg. DataNumen Outlook Repair är ett av de mest rekommenderade reparationsverktygen. Det kan reparera Outlook problem i ett ögonblick.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive skadad mdf och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com