Hur man snabbt exporterar storleksinformation för alla mappar i en PST-fil till en Excel-fil

Om du vill kontrollera storleksinformation för varje mapp i en PST-fil kan du använda metoden som exponeras i den här artikeln. Det exporterar snabbt storleksinformation för alla mappar i en PST-fil till en Excel-fil.

När din PST-fil är för stor kanske du vill kontrollera storleken på varje mapp. Det hjälper dig att enkelt räkna ut vilka som är större och göra lämplig arkivering utifrån storleken. För att kontrollera mappstorleken kan du i allmänhet helt enkelt högerklicka på en mapp och sedan välja “Egenskaper”. I den nya popup-dialogrutan kan du klicka på knappen "Mappstorlek". Men om du har skapat många mappar är det mycket besvärligt att kontrollera storleksinformationen en efter en manuellt. Så om du vill gruppera storleksinformation för alla mappar i en PST-fil kan du använda följande VBA-kod. Det exporterar alla mappnamn och storleksinformation till en Excel-fil på en gång.

Exportera storleksinformation för alla mappar i en PST-fil till en Excel-fil

1. Till att börja med, starta ditt Outlook-program.
2. Byt sedan till fliken "Developer" och klicka på "Visual Basic" -knappen eller tryck på "Alt + F11" för att komma åt VBA-redigeraren.
3. Nästa i fönstret “Microsoft Visual Basic for Applications” öppnar du en modul som inte används.
4. Kopiera sedan och klistra in följande VBA-koder i den här modulen.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Därefter ska du ställa in din säkerhetsnivå för makro i Outlook till låg.
6. Så småningom kan du prova.

• Tryck på F5-tangenten i det aktuella makrofönstret.
• Då kommer du att bli ombedd att välja en PST-fil, som följande bild:
• Efter att ha valt en källfil börjar Outlook exportera storleksinformationen till Excel.
• När makrot är klart får du ett meddelande som skärmdumpen nedan.
• Slutligen kommer du att kunna hitta Excel-filen i den fördefinierade lokala mappen. Excel-filen ser ut som följande:

Hantera frekventa PST-fel

Eftersom Outlook är utsatt för fel kan du någonsin ha lidit många problem i din Outlook. För att bättre och mer flexibelt kunna hantera frustrerande PST-problem, är det tillrådligt att ha en erfaren och ansedd fixverktyg i närheten, såsom DataNumen Outlook Repair. Det kan fixa PST problem som en bris.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive SQL Server återvinning och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com