Hur man snabbt bifogar de specifika sidorna i ett Word-dokument till en Outlook-e-post

MS Word har en direktfunktion som stöder användare att skicka det aktuella Word-dokumentet som en e-postbilaga. Men ibland kanske du bara hoppas kunna bifoga de specifika sidorna i ett Word-dokument till ett Outlook-e-postmeddelande. Nu kommer den här artikeln att dela dig med en metod.

För att skicka ett helt Word-dokument som e-postbilaga i MS Word-applikationen kan du helt enkelt gå till "File" -menyn och flytta till "Save & Send" -fliken, under vilken du hittar knappen "Skicka som bilaga". Men ibland kan det som du vill skicka bara vara specifika sidor i dokumentet. I den här situationen kan du använda metoden som introducerades i det följande för att åstadkomma den.

Bifoga de specifika sidorna i ett Word-dokument till en e-post

1. Först och främst bör du öppna källordet Word-dokument vars specifika sidor du vill skicka i e-post.
2. Efter att ha kommit in i MS Word-fönstret måste du trycka på “Alt + F11” -tangenterna.
3. Därefter får du tillgång till VBA-redigeraren i MS Word.
4. Efter det måste du aktivera "Microsoft Outlook Object Library". Du kan klicka på "Verktyg" > "Referens" för att göra det.
5. Därefter bör du kopiera följande VBA-kod till en modul som inte används.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Slutligen kan du köra detta makro. Tryck bara på F5-tangenten eller tryck på "Kör" -ikonen i verktygsfältet.
7. När makrot är klart visas ett nytt Outlook-e-postmeddelande som bifogas ett utdrag av källordet, som följande skärmdump:

Extrahera maximala data från korrupt Outlook-fil

Om du har använt Outlook i årtionden kan du ha konfronterats med olika Outlook-problem, inklusive popup-inre felmeddelanden, plötsliga kraschar samt allvarliga filskador. På grund av att Scanpst, inbyggt reparationsverktyg, kan bara hantera de små problemen, borde du ha ett externt kraftfullt fixverktyg till hands, säg DataNumen Outlook Repair. Det kan dra ut maximal data från den skadade Outlook-datafilen.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive sql fix och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com