Hur man öppnar alla hyperlänkar med en specifik domän i din Outlook-e-post

När du visar ett Outlook-e-postmeddelande som innehåller många hyperlänkar i kroppen, kanske du ibland bara vill öppna hyperlänkarna med en specifik domän. Här delar vi en metod för att öppna sådana hyperlänkar i bulk.

Med tanke på flera hyperlänkar i ett e-postmeddelande kanske du hoppas kunna kontrollera några av dem istället för alla. Till exempel skulle du bara vilja gruppera hyperlänkar med en specifik domän. I allmänhet måste du klicka en efter en för att öppna dem. Det är väldigt besvärligt. Därför lär vi dig i det följande ett mer bekvämt sätt.

Batchöppna alla hyperlänkar med en specifik domän i e-post

1. För somtart, öppna Outlook VBA-redigeraren enligt “Hur du kör VBA-kod i din Outlook".
2. Därefter aktiverar du hänvisningen till ”MS Word Object Lib i fönstret” Microsoft Visual Basic for Applications ”rary "med hänvisning till"Hur man lägger till ett objekt Library Referens i VBA".
3. Kopiera sedan följande VBA-kod till en oanvänd modul eller ett projekt.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Lägg sedan till detta makro i snabbåtkomstverktygsfältet eller menyfliksområdet.
5. Slutligen, ta följande steg för att prova.

• Välj först eller öppna ett Outlook-e-postmeddelande.
• Klicka sedan på makroknappen.
• Omedelbart öppnas hyperlänkarna med den fördefinierade domänen i e-postmeddelandet i Internet Explorer, som visas i följande bild:

Bli av med Irriterande Outlook-korruption

Även om Outlook är mottagligt för fel och korruption, kan du faktiskt, så länge du ser upp för alla risker, fly från dem med lätthet. Till exempel måste du regelbundet säkerhetskopiera data för Outlook. Dessutom borde du se upp för misstänkta e-postmeddelanden som kan innehålla virus. Sist men inte minst, skulle du bättre förbereda en Outlook-reparation verktyg, såsom DataNumen Outlook Repair. Det kan hjälpa dig i händelse av Outlook-korruption.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive korrupta SQL Server och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com