Hur man automatiskt tar bort Outlook-e-postmeddelanden från en specifik avsändare efter specifika dagar

För att låta din Outlook automatiskt radera e-postmeddelanden från en viss avsändare från specifika dagar kan du läsa den här artikeln. Här visar vi dig detaljerade steg för att använda VBA-kod för att få den.

När det gäller att radera e-post automatiskt kan du först tänka på funktionen "AutoArchive". Det kan emellertid inte filtrera de specifika avsändarna vid automatisk arkivering av e-postmeddelanden. Därför, till exempel, om du automatiskt vill ta bort e-postmeddelanden från en viss avsändare efter x dagar, bör du använda andra sätt, till exempel följande.

Radera e-postmeddelanden automatiskt från en specifik avsändare efter X dagar

1. Starta ditt Outlook-program redan från början.
2. Starta sedan Outlook VBA-redigeraren enligt “Hur du kör VBA-kod i din Outlook".
3. Kopiera sedan följande VBA-kod till projektet "ThisOutlookSession".

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

4. Starta sedan om Outlook för att aktivera makrot.
5. Sedan dess, varje gång när ett nytt e-postmeddelande från den specifika avsändaren anländer till inkorgen, kommer det att tilldelas en specifik utgångstid - de specifika dagarna efter att den mottagits.
6. Sedan, varje gång du startar Outlook, kommer Outlook automatiskt att kontrollera och radera utgångna e-postmeddelanden från den specifika avsändaren.

Återställ Outlook-data efter korruption

Du kanske har stött på en mängd olika fel och problem i Outlook. Har du då konfronterat Outlook-korruption? Om du till exempel ofta avslutar Outlook felaktigt, tenderar din PST-fil att skadas. I ett sådant fall kan du i allmänhet välja att hämta Outlook-data från säkerhetskopior. Eller så kan du antingen använda verktyg för reparation av inkorgen eller ett tillförlitligt externt verktyg, t.ex. DataNumen Outlook Repair.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive återhämta sql och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com