Hur man tar bort alla läskvitton i din grupp

För att bekräfta att mottagarna har läst ditt e-postmeddelande kan du begära ett läskvitto när du skriver det. I den här situationen kan din inkorg vara full av sådana läskvitton. Nu kommer det här inlägget att lära dig hur du raderar dem permanent i grupp.

Efter att ha läst artikeln “Så här grupperar du bort alla leveranskvitton i din Outlook”, Du kanske tänker på metoden att massradera alla läskvitton. Faktum är att den uppenbara skillnaden mellan de två typerna av kvitton är deras ämnen. Leveranskvittot innehåller "Levereras" i ämnet men läskvittot innehåller "Läs" istället. Därför kan du använda samma sätt för att radera alla läskvitton. I det följande kommer vi att lära dig de konkreta stegen i detalj.

Batch Radera alla läskvitton

1. Börja med att starta din Outlook.
2. Gå sedan till Outlook VBA-redigeraren via "Alt + F11" enligt "Hur du kör VBA-kod i din Outlook".
3. Därefter öppnar du en tom modul i det nya fönstret och lägger in följande kod i den.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Klicka därefter in i den första underrutinen.
5. Slutligen trycker du på “F5” -tangentknappen.
6. På en gång fungerar makrot för att ta bort alla läskvitton från din Outlook.
7. När det är klart får du en fråga om resultatet, som skärmdumpen nedan.
8. För närvarande kan du kontrollera dina e-postmappar. Alla läskvitton är borta.

Försvara Outlook-data

Även om Outlook-filen visserligen är mottaglig för korruption kan vi vidta åtgärder för att skydda den. Vi bör till exempel hålla Outlook-filen i liten storlek, skydda den från skadliga faktorer och säkerhetskopiera den regelbundet. Sist men inte minst, skulle du bättre förbereda ett kraftfullt externt PST-reparationsverktyg, som DataNumen Outlook Repair. Det kommer att få stora effekter på reparationen korrupta Outlook fil.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive sql reparation och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com