Så här ställer du in Outlook online eller offline automatiskt baserat på dina arbetstider

Vissa användare vill göra Outlook att automatiskt växla mellan online- och offline-status baserat på deras arbetstid. Så i den här artikeln delar vi en snabb metod med dig.

Egentligen är det väldigt enkelt att ställa in Outlook online eller offline. För att förvandla Outlook till offline-status kan du bara växla till fliken "Skicka / ta emot" och trycka på "Arbeta offline" -knappen. Och för att återgå till onlinestatus trycker du helt enkelt på den här knappen igen. Vissa användare hoppas dock att Outlook automatiskt kan växla till offline-status när det är utom arbetstid och återgå till online under arbetstid. Även om Outlook inte tillhandahåller en sådan funktion kan du fortfarande använda följande VBA-kod för att uppnå den.

Ställ in Outlook online eller offline baserat på dina arbetstider

1. Från början, start din Outlook-applikation.
2. Sedan, efter att ha fått åtkomst till din Outlook, bör du öppna mappen Uppgifter.
3. Därefter bör du skapa ett dagligt återkommande uppgiftsobjekt.

• Klicka på knappen "Ny uppgift" i menyfliksområdet.
• Mata sedan in "Offline" i ämnesraden Uppgift.
• Klicka sedan på knappen "Återkommande" under fliken "Uppgift".
• I popup-dialogrutan väljer du “Dagligt” återkommande mönster, aktiverar “Inget slutdatum” och trycker på “OK”.
• Därefter bör du aktivera en påminnelse vid "5:00".
• Slutligen trycker du på knappen "Spara och stäng".

4. Därefter måste du skapa en annan daglig återkommande uppgift som heter "Online" och aktivera en påminnelse vid "8:00 AM", som visas som bilden nedan:
5. Därefter trycker du på “Alt + F11” -knapparna i huvudfönstret i Outlook.
6. Därefter får du tillgång till Outlook VBA-redigeraren, där du måste hitta och öppna projektet "ThisOutlookSession".
7. Senare kopiera följande VBA-kod till detta projekt.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. Så småningom kan du ändratart Outlook för att aktivera detta makro.
9. Från och med nu kommer din Outlook att vara online under arbetstid och automatiskt växla till offline-status utanför arbetstid.

Din sista utväg i händelse av Outlook-kraschar

Även om Outlook har flera funktioner, kan Outlook fortfarande inte hålla sig borta från fel och skador. Men kom inte i panik. Så länge du gör tillräckliga försiktighetsåtgärder kan du fortfarande skydda dina Outlook-data effektivt. Till exempel bör du säkerhetskopiera dina PST-filer regelbundet eftersom säkerhetskopior gör att du kan komma tillbaka korrupt PST data. Håll också ett kraftfullt reparationsverktyg, som DataNumen Outlook Repair, är också en fråga om nödvändighet.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive fixa mdf och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com