Hur man automatiskt exporterar bifogad information om inkommande Outlook-e-postmeddelanden till en Excel-arbetsbok

Vissa användare vill automatiskt spela in informationen om bilagorna i varje inkommande e-postmeddelande. Denna artikel kommer att dela en snabb tid att förstå det med lätthet.

Om du är van att exportera bifogad information för varje inkommande Outlook-e-post till en Excel-fil kanske du längtar efter några tillvägagångssätt som kan låta Outlook automatiskt utföra detta arbete. Därmed kan du bli av med att spåra bilagor manuellt. Lyckligtvis, även om Outlook inte tillhandahåller en sådan direkt funktion, kan du ändå uppnå det med lite skript. Nu kommer vi att lära dig steg för steg.

Exportera automatiskt bifogad information om inkommande e-post till Excel

1. Starta först Outlook-applikationen.
2. Gå sedan till VBA-redigeraren via “Alt + F11”.
3. Kopiera sedan följande VBA-kod till en modul.

Sub AutoExportAttachmentInfo(objMail As Outlook.MailItem)
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nLastRow As Integer
    Dim objAttachment As Outlook.Attachment
 
    If objMail.Attachments.Count > 0 Then
       'Change the path to the specific Excel file
       strExcelFile = "E:\Attachment Info.xlsx"
 
       Set objExcelApp = CreateObject("Excel.Application")
       objExcelApp.Visible = True
       Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
       'Export Attachment info to Excel
       For Each objAttachment In objMail.Attachments
           nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
           With objExcelWorksheet
                .Cells(nLastRow, 1) = objMail.Subject
                .Cells(nLastRow, 2) = objMail.SenderEmailAddress
                .Cells(nLastRow, 3) = objAttachment.FileName
                .Cells(nLastRow, 4) = objMail.ReceivedTime
           End With
       Next
 
       objExcelWorksheet.Columns("A:C").AutoFit
       objExcelWorkbook.Close True
       objExcelApp.Quit
    End If
End Sub

4. Avsluta sedan VBA-redigeraren.
5. Skapa därefter en regel för att automatiskt köra detta makro i varje inkommande e-post.

• Först och främst, gå till "Arkiv" -menyn.
• Klicka sedan på knappen "Hantera regler och varningar".
• Klicka på "Ny regel" i dialogrutan "Regler och varningar".
• I dialogrutan "Regelguide" väljer du "Använd regel på meddelanden som jag får" och klickar på "Nästa".
• Därefter ställer du in regelvillkor enligt dina behov och trycker på "Nästa".
• I steget "Välj åtgärder", välj "Kör ett skript" och välj "AutoExportAttachmentInfo" -skriptet.
• Slutligen följ guiderna på skärmen för att slutföra regelinställningen.

6. Från och med nu, varje gång när ett nytt e-postmeddelande anländer till din brevlåda, om det har några bilagor, exporterar Outlook automatiskt bifogad information till den fördefinierade Excel-filen.

Ladda aldrig ner misstänkta bilagor

Har du någonsin fått några e-postmeddelanden från okända avsändare och innehåller bilagor? Vanligtvis föreslås det att man inte lätt litar på sådana bilagor så att de kan vara med virus. Så länge du laddar ner dem kan dina Outlook-data infekteras. Vid den tiden måste du fixa Outlook fil. Det är visserligen knotigt om du inte tillgriper ett skickligt reparationsverktyg, till exempel DataNumen Outlook Repair.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive återhämta Sql Server och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com