2 sätt att gruppera alla Outlook-e-postmeddelanden äldre än ett specifikt datum som läst

Efter att ha importerat flera gamla e-postmeddelanden till Outlook och dessa e-postmeddelanden är i "oläst" -status måste du gruppera dem som lästa. Nu, i den här artikeln, kommer vi att visa två snabba metoder för dig.

Ibland kan du behöva gruppmarkera flera e-postmeddelanden som lästa. Till exempel har du en gammal PST-fil som innehåller många gamla e-postmeddelanden. Sedan importerar du e-postmeddelandena till din egen Outlook PST-fil. Men efter import visas dessa e-postmeddelanden som "olästa" som standard. Vid den här tiden vill du markera dessa e-postmeddelanden, äldre än ett visst datum, som lästa. Här kommer vi att titta på detta krav för att dela två praktiska och effektiva metoder.

Metod 1: Partimärke hittade e-postmeddelanden som läst manuellt

1. Till att börja med, öppna en e-postmapp.
2. Klicka sedan i sökrutan.
3. Klicka sedan på knappen "Sök" i "Sök" -knappen i gruppen "Omfattning".
4. Ange sedan kriterierna ”skickat: <= 2018/5/21” i sökrutan. Ändra “2018/5/12” till önskat datum.
5. När sökningen är klar markerar du alla hittade e-postmeddelanden via “Ctrl + A”.
6. Högerklicka slutligen och välj alternativet "Markera annons som läst".

Metod 2: Batchmark-e-postmeddelanden äldre än specifikt datum som läst med VBA

1. Till att börja med startar du VBA-redigeraren i Outlook enligt “Hur du kör VBA-kod i din Outlook".
2. Kopiera sedan följande kod till en modul.

Dim dDate As Date

Sub MarkEmailsOlderThanSpecificDateRead()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    dDate = InputBox("Enter the specific date:", , "2018/5/11")
 
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
 
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If TypeOf objItem Is MailItem Then
           Set objMail = objItem
 
           If objMail.SentOn <= dDate Then
              If objMail.UnRead = True Then
                 objMail.UnRead = False
                 objMail.Save
              End If
           End If
        End If
    Next
 
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

3. Tryck därefter på “F5” -knappen för att köra detta makro just nu.
4. Senare, i den lilla popup-dialogrutan, anger du det specifika datumet och trycker på “OK”.
5. Så småningom kommer alla e-postmeddelanden som är äldre än det specifika datumet att markeras som lästa.

Återställ komprometterad Outlook-fil

Outlook PST-filer kan skadas efter att Outlook kraschar oväntat då och då. Om du har en uppdaterad säkerhetskopia kan du bara återställa Outlook data med din säkerhetskopia. Annars har du inget annat val än att söka en specialiserad expert eller ett verktyg, t.ex. DataNumen Outlook Repair för att reparera Outlook-filen.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive MDF-fix och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com