2 snabba sätt att extrahera avsnitt från ditt Word-dokument

I den här artikeln kommer vi att erbjuda dig två snabba och enkla sätt att extrahera avsnitt från ditt Word-dokument till ett annat eller flera.

Det händer ganska ofta att extrahera innehåll från ett dokument till ett annat. Och i vår tidigare artikel har vi diskuterat hur man extraherar sidor från dokument. För detaljerad information kan du hänvisa till den här artikeln: 2 snabba sätt att extrahera enskilda sidor från ditt Word-dokument

Idag visar vi dig hur du extraherar efter avsnitt.    

Metod 1: Extrahera nuvarande avsnitt till ett nytt dokument

1. Placera först markören i ett målavsnitt.
2. Tryck sedan på “Alt + F11” för att anropa VBA-redigeraren i Word.
3. Klicka sedan på "Normal" i den vänstra kolumnen.
4. Klicka på ”Infoga” i menyraden.
5. Välj sedan "Modul" på den rullgardinsmenyn.
6. Dubbelklicka för att öppna den nya modulen och klistra in följande koder där:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Klicka sedan på "Kör" i menyraden eller tryck på "F5".
8. Då kommer popup-fönstret att dyka upp. Välj en plats för att lagra det nya dokumentet och klicka på “OK”.
9. Och i rutan "Filnamn" anger du namnet på den nya filen och klickar på "OK".

Nu har du extraherat avsnittet till ett nytt dokument.

Metod 2: Extrahera varje avsnitt i dokument till enskilda nya

Det här sättet kan hjälpa dig att bearbeta alla avsnitt i ett dokument. Naturligtvis behöver vi ett makro också.

1. Till att börja med, öppna måldokumentet.
2. Följ sedan stegen i metod 1 för att installera och köra ett makro.
3. Endast den här gången ersätter du det här makrot med det här:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. I fönstret "Bläddra" väljer du ändå en lagringsväg och klickar på "OK".

Åtgärda irriterande ordfel

Det är vanligt att stöta på några Word-fel när du använder det. Irriterande kan det vara, vi måste ta oss tid återställa ord Så snart som möjligt. För ju längre vi fördröjer det, desto svårare kan dataförlusten bli. Därför föreslås att du får tag på ett reparationsverktyg i förväg.

Författarintroduktion:

Vera Chen är en dataåterställningsexpert i DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive skadade xls och pdf reparera programvaruprodukter. För mer information besök www.datanumen.com