Как установить разное время напоминания по умолчанию для разных типов помеченных элементов в Outlook

По умолчанию Outlook автоматически использует время напоминания задач по умолчанию для всех видов помеченных элементов. Тем не менее, если вы хотите использовать разное время напоминания для помеченных элементов в зависимости от типа элемента, вы можете обратиться к методу, представленному в этой статье.

Outlook позволяет установить время напоминания по умолчанию для всех помеченных элементов, независимо от типа элемента. Вы можете перейти в меню «Файл» и нажать «Параметры». Затем в окне «Параметры Outlook» вы можете увидеть параметр «Время напоминания по умолчанию» на вкладке «Задачи», как показано на следующем снимке экрана.

Тем не менее, мost пользователи надеются использовать разное время напоминания для разных видов отмеченных элементов, например, «9:00» для отмеченных писем и «17:30» для отмеченных контактов. Теперь в дальнейшем мы сосредоточимся на этом примере, чтобы представить метод.

Установите разное время напоминания по умолчанию для разных типов помеченных элементов

1. К starт с, запустите приложение Outlook.
2. Затем откройте редактор Outlook VBA со ссылкой на «Как запустить код VBA в Outlook».
3. В следующем окне «Microsoft Visual Basic для приложений» скопируйте следующий код в проект «ThisOutlookSession».

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. После этого резtart Outlook, чтобы активировать этот макрос.
5. С этого момента каждый раз, когда вы помечаете электронное письмо, время напоминания будет установлено на «10:00» в день, когда нужно пометить.
6. И когда вы помечаете контакт, время напоминания будет установлено на «17:30» в день выполнения пометки.

Гибко решайте проблемы Outlook

Вы можете столкнуться со всеми видами проблем в Outlook. Таким образом, вы должны изучить некоторые меры, чтобы справиться с ними заранее. Например, если ваш Outlook частоtarts, вам нужно восстановить Office или отключить сторонние надстройки и т. д. Или, если ваш Outlook PST скомпрометирован, вы можете сначала попробовать инструмент для ремонта входящих. Когда это не удается, вы можете продолжать прибегать к мощному внешнему инструменту, например DataNumen Outlook Repair.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая восстановление мдф и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com