Как пакетно открыть все гиперссылки с определенным доменом в электронной почте Outlook

При просмотре электронной почты Outlook, которая содержит много гиперссылок в теле, иногда вы можете захотеть быстро открыть только гиперссылки с определенным доменом. Здесь мы поделимся методом массового открытия таких гиперссылок.

Столкнувшись с несколькими гиперссылками в одном электронном письме, вы можете надеяться проверить некоторые из них, а не все. Например, вы хотите пакетно открывать только гиперссылки с определенным доменом. В общем, вы должны нажать один за другим, чтобы открыть их. Это очень хлопотно. Поэтому в дальнейшем мы научим вас более удобному способу.

Пакетное открытие всех гиперссылок с определенным доменом в электронной почте

1. Для насtart, войдите в редактор Outlook VBA в соответствии с «Как запустить код VBA в Outlook».
2. Затем в окне «Microsoft Visual Basic для приложений» включите ссылку на «MS Word Object Lib».rarу» со ссылкой на «Как добавить объектную библиотекуrary Ссылка в VBA».
3. Затем скопируйте следующий код VBA в неиспользуемый модуль или проект.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Затем добавьте этот макрос на панель быстрого доступа или на ленту.
5. Наконец, сделайте следующие шаги, чтобы попробовать.

• Прежде всего, выберите или откройте электронную почту Outlook.
• Затем нажмите кнопку макроса.
• Сразу же гиперссылки с предопределенным доменом в электронном письме будут открыто в Internet Explorer, как показано на следующем изображении:

Избавьтесь от раздражающей порчи Outlook

Хотя Outlook подвержен ошибкам и повреждениям, на самом деле, если вы следите за всеми рисками, вы можете легко избежать их. Например, вам необходимо регулярно делать резервные копии данных для Outlook. Кроме того, вы должны следить за подозрительными электронными письмами, которые могут содержать вирусы. И последнее, но не менее важное: вам лучше подготовить Восстановление Outlook утилита, например DataNumen Outlook Repair. Он способен помочь вам в случае повреждения Outlook.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая и коррумпированных лиц SQL Server и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com