Как автоматически использовать разные цвета шрифта для ответов и пересылки электронных писем с помощью Outlook VBA

Перспективные решения 29 сентября, 2025
Поделись сейчас:

By default, you cannot let Outlook auto use different font colors for replying and forwarding emails. Therefore, if you have such a requirement, you can read this post to learn a smart approach.

Outlook позволяет указать только шрифт, используемый как для ответа, так и для пересылки электронных писем. Вы можете перейти в «Файл»> «Параметры». Затем в «Параметры Outlook» перейдите на вкладку «Почта» и нажмите кнопку «Канцелярские товары и шрифты…». В следующем окне вы можете увидеть кнопку «Шрифт» в разделе «Ответы или переадресация сообщений». Нажмите на нее, и тогда вы сможете установить определенный цвет шрифта для ответа и пересылки электронных писем.

Изменить шрифт при ответе или пересылке сообщений

Однако многие пользователи надеются использовать разные цвета шрифта для ответов или пересылки электронных писем. Хотя Outlook не предоставляет для этого никаких прямых функций, это все же можно реализовать с помощью кода VBA. Теперь читайте дальше, чтобы получить такой фрагмент кода VBA.

Автоматическое использование разных цветов шрифта для ответов и пересылки электронных писем

  1. Для начала запустите приложение Outlook.
  2. Затем запустите редактор VBA со ссылкой на «Как запустить код VBA в Outlook».
  3. Далее в соответствии с «Как добавить ссылку на библиотеку объектов в VBA“, add the reference to “MS Word Object Library”.
  4. Затем скопируйте следующий код в проект ThisOutlookSession.
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

Код VBA - автоматическое использование разных цветов шрифта для ответов и пересылки электронных писем

  1. После этого перезапустите Outlook, чтобы активировать этот макрос.
  2. Наконец, вы можете попробовать.
  • Выберите или откройте электронное письмо.
  • Затем нажмите кнопку «Ответить». При ответе на электронную почту вы можете ввести несколько слов в теле письма. Цвет шрифта должен быть розовым."Розовый" шрифт в "Ответить"
  • Или нажмите кнопку «Ответить всем». В новом письме «отвечаю всем» введите слова в теле письма. Цвет шрифта обязательно зеленый.«Зеленый» шрифт в «Ответить всем»
  • Аналогичным образом нажмите кнопку «Вперед». В пересылаемой почте новые слова будут выделены синим цветом.«Синий» шрифт в «Вперед»

Воспользуйтесь надежным программным обеспечением

В случае Повреждение Outlook, most users tend to resort to Outlook recovery software. There are a great amount of such programs available in market. And some of them are even free of charge. Nevertheless, you ought to beware of those from unknown sources in that they may make the current case worse and worse. You ought to take aid of a reliable and experienced tool, like DataNumen Outlook Repair.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая поврежденный sql и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com

Поделись сейчас:

Комментарии закрыты.