Как автоматически создать новую встречу, когда электронное письмо помечено в Outlook

Перспективные решения 29 сентября, 2025
Поделись сейчас:

Некоторые люди хотят автоматически или быстро создать новую встречу в Outlook, когда они помечают электронное письмо. В этой статье будет представлен подход к реализации этого с помощью Outlook VBA.

Иногда я могу получить электронное письмо, в котором упоминается встреча или встреча. Но это просто электронное письмо, а не обычный элемент собрания в Outlook. В этом случае мне нужно создать новую встречу в календаре Outlook вручную. Это немного хлопотно. Поэтому я хочу, чтобы Outlook мог автоматически создавать новую встречу. Тем не менее, Outlook не имеет встроенной поддержки для автоматического создания новой встречи, когда мы помечаем электронное письмо. Поэтому, чтобы добиться этого, я решил использовать Outlook VBA. Вот подробные коды и шаги VBA.

Автоматическое создание новой встречи, когда электронное письмо помечено

  1. Прежде всего, перейдите на вкладку «Разработчик» и нажмите кнопку «Visual Basic» в группе «Код».Кнопка Visual Basic
  2. Затем в новом окне «Microsoft Visual Basic для приложений» вам нужно дважды щелкнуть «ThisOutlookSession», чтобы открыть этот проект.
  3. Затем скопируйте и вставьте в него следующие коды VBA.
Public WithEvents olItems As Outlook.Items

Private Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub olItems_ItemChange(ByVal Item As Object)
    Dim oAppt As AppointmentItem
    Dim strMsg As String
    Dim nRes As Integer
 
    On Error Resume Next
 
    If TypeName(Item) = "MailItem" And Item.IsMarkedAsTask = True Then
       strMsg = "Do you want to create a new appointment"
       nRes = MsgBox(strMsg, vbYesNo + vbQuestion, "Confirm Creating Appointment")
       If nRes = vbYes Then
          Set oAppt = Application.CreateItem(olAppointmentItem)
          With oAppt
               .Subject = "New Appt: " & Item.Subject
               .Location = InputBox("Enter the Location, please.")
               'Type the concrete time, such as "12/29/2015 15:30"
               .Start = InputBox("Enter a specific time (format: MM/DD/YYYY hh:mm), please.")
               .Duration = 120
               .Body = "New Appointment: " & vbCrLf & vbCrLf & Item.Body
               .Attachments.Add Item
               .ReminderSet = True
               .ReminderMinutesBeforeStart = 30
               'Use ".Save" to directly save the new appointment
               .Display
          End With
       End If
 
      'To clear the flag on the email
      'If you want to keep email flagged, remove the following 4 lines
       With Item
            .ClearTaskFlag
            .Save
       End With
    End If
End Sub

Скопируйте коды VBA в ThisOutlookSession.

  1. Впоследствии вы должны использовать «Цифровой сертификат для проектов VBA», чтобы создать новый сертификат и подписать текущий проект «ThisOutlookSession».Цифровая подпись проекта ThisOutlookSession
  2. После этого вы можете выйти из окна «Visual Basic» и изменить настройки макроса, чтобы разрешить только макросы с цифровой подписью.Разрешить только макросы с цифровой подписью
  3. В конце концов, вы можете попробовать.
  • Во-первых, отправьте электронное письмо и нажмите значок «Пометить». Вы получите подсказку, как на следующем снимке экрана:Подтвердить создание встречи
  • После выбора «Да» вам потребуется указать местоположение и нажать кнопку «ОК».Введите местоположение
  • Затем нужно указать время встречи.Введите конкретное время
  • Наконец, после нажатия «ОК» откроется новая встреча, показанная на изображении ниже:Новая встреча

Примечание:

  1. В этих кодах VBA напоминание по умолчанию установлено на 30 минут. Вы можете изменить его в кодах по своему желанию.
  2. Коды устанавливают продолжительность приема 120 минут, а именно 2 часа. Вы можете изменить строку «.Duration = 120» в соответствии с вашими потребностями.
  3. Если вы не указали конкретное время, новая встреча будет установлена ​​на текущую дату и время по умолчанию.
  4. Вы можете добавить строку «.Save», чтобы сохранить встречу напрямую.

Устранение проблем с Outlook

Известно, что Outlook может страдать от различных проблем. Наихудшей ситуацией должны быть повреждения Outlook. Если ваш файл Outlook поврежден и у вас есть резервная копия, вы можете легко восстановить поврежденные данные Outlook из резервных копий. Но если у вас нет резервной копии, вам нужно будет восстановить поврежденный файл Outlook. В этом случае вы можете использовать встроенный инструмент восстановления Scapst.exe или прибегнуть к более опытному инструменту, например DataNumen Outlook Repair.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая ремонт SQL Server проблема с базой данных мдф и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com

Поделись сейчас:

Комментарии закрыты.