3 быстрых способа удалить пустые строки и столбцы в таблице Word

В этом пost, мы объясним вам 3 быстрых способа удалить пустые строки и столбцы в вашей таблице Word.

Таблицы необходимы для документа, особенно для хранения различных типов данных. Иногда длинная таблица может превышать страницу и простираться на несколько. Поэтому, когда таблица становится длинной и сложной, вы можете принять меры для ее упрощения. Например, вы можете удалить ненужные пустые строки и столбцы.

Ниже приведены 3 метода, которые вы можете использовать.

Способ 1: удалить пустые строки и столбцы вручную

1. Во-первых, выберите строку или столбец пустыми.
2. Затем щелкните правой кнопкой мыши, чтобы открыть контекстное меню. В меню выберите «Удалить строки» или «Удалить столбцы» соответственно.

К сожалению, вы не можете выбрать несколько непоследовательных строк или столбцов и удалить их вместе с этим способом. Для этого требования вы можете обратиться к нашей предыдущей статье: 5 быстрых методов для пакетного удаления нескольких строк или столбцов в таблице Word

Метод 2: пакетное удаление всех пустых строк и столбцов в таблице

Метод 1 имеет свои ограничения. Итак, мы предложим вам способ пакетного удаления строк и столбцов в таблице с помощью кодов VBA.

1. Для начала поместите курсор внутрь tarполучить стол.
2. Во-вторых, запустите редактор VBA, нажав «Alt + F11».
3. В редакторе сначала нажмите «Обычный» проект.
4. Затем нажмите вкладку «Вставить» в строке меню.
5. В выпадающем меню выберите «Модуль».
6. Дважды щелкните модуль, чтобы открыть его, и вставьте туда следующие коды:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Наконец, нажмите кнопку «Выполнить» в строке меню или нажмите «F5».

Через несколько секунд вы удалите все пустые строки и столбцы в этой таблице.

Метод 3: пакетное удаление всех пустых строк и столбцов во всех таблицах документа

1. Во-первых, повторите шаги метода 2, чтобы установить и запустить макрос.
2. Только на этот раз замените этот макрос следующим:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Восстановить сломанный документ

Существует больше, чем способ получить lost данные обратно в настоящее время. Например, использование резервных копий всегда остается вашим главным приоритетом. Если это не удовлетворяет вашу потребность в получении последней информации, вы можете попробовать ремонт документов инструмент.

Об авторе:

Вера Чен — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая xlsx ремонт и pdf ремонт программных продуктов. Для получения дополнительной информации посетите www.datanumen.com