Slik slår du raskt sammen og eksporterer flere Excel-arbeidsbokvedlegg til én arbeidsbok i Outlook

Når du mottar en e-post vedlagt med flere Excel-arbeidsbøker, hvis du vil sjekke innholdet i alle arbeidsbøkene i en enkelt arbeidsbok, kan du bruke måten i denne artikkelen. Den eksporterer flere Excel-arbeidsbokvedlegg til én arbeidsbok.

For å se alle Excel-arbeidsbokvedleggene til en e-post i én Excel-arbeidsbok, bør du først kombinere og eksportere disse vedleggene til én enkelt arbeidsbok. I stedet for å gjøre det manuelt, kan du bruke følgende metode for å oppnå det uten problemer. Det vil lære deg å bruke VBA-kode for å oppnå det. Når det gjelder hvordan du bruker VBA, kan du se sost "Hvordan kjøre VBA-kode i Outlook".

Slå sammen og eksporter flere Excel-arbeidsbokvedlegg til én arbeidsbok

1. For somtart, start Outlook-applikasjonen.
2. Gå deretter til Outlook VBA-redigeringsprogram.
3. Deretter, i det nye "Microsoft Visual Basic for Applications"-vinduet, må du aktivere "MS Excel Object Library", som du kan referere til artikkelen om - "Hvordan legge til et objekt Library Referanse i VBA".
4. Kopier deretter følgende VBA-kode til et prosjekt eller en modul.

Sub CombineMultipleExcelWorkbookAttachmensIntoOne()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim strFile As String
    Dim objCurrentSheet As Excel.Worksheet
    Dim objCurrentBook As Excel.Workbook
    Dim objSheet As Excel.Worksheet
    Dim objFileSystem As Object
 
    On Error Resume Next
    'Create a new temp folder
    strTempFolder = "E:\Temp" & Format(Now, "yyymmddhhmmss") & "\"
    MkDir (strTempFolder)
 
    'Save selected attachments
    Set objSelectedAttachments = Outlook.Application.ActiveExplorer.AttachmentSelection
    For Each objAttachment In objSelectedAttachments
        objAttachment.SaveAsFile (strTempFolder & objAttachment.FileName)
    Next
 
    'Copy all the workbooks into a new file
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelWorkbook.Activate
 
    strFile = Dir(strTempFolder)
    Do While strFile <> ""
       Set objCurrentBook = objExcelApp.Workbooks.Open(strTempFolder & strFile)
       For Each objCurrentSheet In objCurrentBook.Sheets
           objCurrentSheet.Copy Before:=objExcelWorkbook.Sheets(1)
       Next
 
       objExcelApp.Workbooks(strFile).Close
       strFile = Dir()
    Loop
 
    'Remove empty sheets
    objExcelApp.DisplayAlerts = False
    For Each objSheet In objExcelWorkbook.Worksheets
        If objExcelApp.WorksheetFunction.CountA(objSheet.Cells) = 0 Then
           objSheet.Delete
        End If
    Next
    objExcelApp.DisplayAlerts = True
 
    'Delete the temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Etter det kan du lukke vinduet og legge til den nye makroen til Quick Access Toolbar.
6. Senere, pitch på kilde-e-posten i e-postlisten.
7. Hold deretter nede "Ctrl" for å velge Excel-arbeidsbokvedleggene du vil eksportere.
8. Klikk deretter på makroknappen i verktøylinjen for hurtigtilgang.
9. Når makroen er fullført, vises en ny Excel-arbeidsbok. Den vil inneholde innholdet i de tidligere valgte Excel-arbeidsbøkene.

Fall tilbake på et kraftigere eksternt reparasjonsverktøy

Når du møter Outlook-korrupsjon, most brukere vil ha en tendens til å benytte seg av verktøy for reparasjon av innboks å prøve i første omgang. Det vil imidlertid ikke være mye hjelp i tilfelle alvorlig skade. På det tidspunktet har du ikke noe annet valg enn å ta hjelp av et eksternt pålitelig og erfarent verktøy, som f.eks DataNumen Outlook Repair.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert mdf gjenoppretting og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med