Slik ekskluderer du raskt originale "CC"-mottakere når du bruker "Svar alle" i Outlook

Når du bruker "Svar alle", vil den svarte e-posten også inkludere "CC"-mottakerne av den opprinnelige e-posten i "CC"-feltet. Men hvis du ønsker å ekskludere denne typen mottaker, kan du bruke metoden som ble introdusert i denne artikkelen.

Noen ganger ønsker du å svare på en e-post til den opprinnelige avsenderen og "Til"-mottakere. I dette scenariet vil du definitivt tenke på å bruke alternativet "Svar alle". Men på denne måten, hvis den opprinnelige e-posten også har "CC"-mottakere, vil "Svar alle"-e-posten automatisk kopiere "CC"-mottakerne til "CC"-feltet. Hvis du ikke vil svare på dem, må du fjerne dem manuelt, noe som er litt plagsomt. Nå, i det følgende, vil vi lære deg hvordan du lar Outlook auto utføre det i henhold til dine behov.

Ekskluder raskt originale "CC"-mottakere når du bruker "Svar alle"

1. For en start, start Outlook.
2. Deretter får du tilgang til VBA-editor ved å lese forrige artikkel - "Hvordan kjøre VBA-kode i Outlook".
3. Deretter kopierer du følgende VBA-kode inn i "ThisOutlookSession" -prosjektet.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

4. Deretter starter du Outlook på nytt for å aktivere dette nye prosjektet.
5. Siden da, hver gang du trykker på "Svar alle"-knappen, vil du få en melding, som vist i bildet nedenfor, som spør om du vil ekskludere originale CC-mottakere.
6. Hvis du velger "Ja", vil Outlook automatisk fjerne mottakerne i "CC"-feltet.

Hold deg godt forberedt på Outlook-skader

Som vi alle vet, kan ingen 100 % garantere at de er immune mot skader fra Outlook. Derfor er det viktig for alle vanlige Outlook-brukere å ta mange forholdsregler. Først og fremst er en av de viktigste å ha en konsekvent og oppdatert sikkerhetskopi av Outlook-data. Deretter er det nødvendig å lære hvordan man bruker reparasjonsverktøyet for innboksen. Sist, men ikke minst, er det klokt og anbefalt å ha en erfaren Outlook-fiks verktøy i nærheten, som f.eks DataNumen Outlook Repair.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert gjenopprette mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med