Hvordan forsinke leveringen til et bestemt medlem når du sender en Outlook-e-post til en kontaktgruppe

Outlook-løsninger September 29, 2025

Denne artikkelen vil dele et stykke VBA-kode, som kan tillate deg å raskt utsette leveringen til et bestemt medlem når du sender en e-post til en kontaktgruppe i Outlook.

Når du skriver og sender en Outlook-e-post til en kontaktgruppe, hvis du ønsker å utsette sendingen av denne e-posten til et bestemt medlem i denne gruppen, kan du bruke følgende metode for å realisere det. Det vil automatisk utvide kontaktgruppen og generere en samme e-post som er forsinket til det spesifikke medlemmet. Les nå for å få de forseggjorte trinnene.

Utsett leveringen til et bestemt medlem når du sender en Outlook-e-post til en kontaktgruppe

Utsett leveringen til et bestemt medlem når du sender en e-post til en kontaktgruppe

  1. Til start med, start Outlook-programmet.
  2. Deretter, i det nye hovedvinduet i Outlook, bør du trykke på "Alt + F11" -tastene.
  3. Deretter får du tilgang til Outlook VBA-editoren, der du må sette inn en ny modul eller bare åpne en modul som ikke er i bruk.
  4. Etter det kan du kopiere og lime inn følgende VBA-kode i denne modulen.
Sub DelayEmail_aSpecificMemberinContactGroup()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objDelayedMail As MailItem
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact group in "To" field
          For i = objRecipients.count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend

    'Find the specific memebr in the recipients
    For Each objRecipient In objRecipients
        If objRecipient.Address = "shelly@datanumen.com" Then
 
           'Create a same email
           Set objDelayedMail = objCurrentMail.Copy
           With objDelayedMail
                .To = ""
                .Recipients.Add objRecipient.Address
                .Recipients.ResolveAll
                'Change the deferred delivery time as per your needs
                .DeferredDeliveryTime = (Date + 1) & " 09:00:00"
                .Send
          End With
 
          objRecipient.Delete
       End If
    Next
 
    objCurrentMail.Send
End Sub

VBA-kode - Utsett leveringen til et bestemt medlem når du sender en Outlook-e-post til en kontaktgruppe

  1. Deretter, for senere praktisk tilgang, bør du legge til den nylig lagt til makroen til hurtigtilgangsverktøylinjen i meldingsvinduet.
  2. Og så bør du endre Outlook-makroinnstillingene dine for å aktivere alle makroer i "Makroinnstillinger" i "Tillitssenter".
  3. Til slutt kan du ta et skudd.
  • Skriv først en slik e-post til kontaktgruppen som vanlig.
  • Deretter kan du klikke på den nye makroknappen i hurtigtilgangsverktøylinjen.
  • Med en gang vil en samme e-post opprettes og sendes ut til det spesifikke medlemmet til det planlagte tidspunktet.
  • I mellomtiden vil gjeldende e-post bli sendt ut til resten av medlemmene i kontaktgruppen.

Hold øye med alle risikoer rundt Outlook

I samtidenrary-epoken, virus og spionprogrammer blir stadig mer utbredt. Det er vanligvis forkledd som ufarlig e-post. Derfor bør du se opp for ulike risikoer rundt Outlook, for eksempel ondsinnede e-poster. Du må passe deg for e-postene fra ukjente kontakter. Også for å fikse Outlook så snart PST-filen din blir angrepet av skadelig programvare, må du forberede et erfarent reparasjonsverktøy, som DataNumen Outlook Repair.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert ødelagt sql og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.