2 måter å raskt slå sammen flere Word-dokumenter til ett via VBA

I denne artikkelen er vi glade for å dele med deg 2 måter å raskt slå sammen flere Word-dokumenter til ett via VBA.

I Word er det standard innebygd funksjon for å hjelpe brukeren med å kombinere eller slå sammen flere dokumenter til ett. Detaljer er forklart i denne artikkelen: Hvordan kombinere og slå sammen flere Word-dokumenter til ett

Med den metoden må du gjøre et par klikk, og innholdet i neste dokument kommer alltid rett etter det forrige. Derfor ønsker vi å tilby deg raskere måter å gjøre det på.

Metode 1: Slå sammen valgte dokumenter til ett

1. Først og fremstost, opprett et nytt tomt dokument.
2. Utløs VBA-editor i Word ved å trykke "Alt + F11".
3. Klikk deretter på "Normal".
4. Klikk deretter "Sett inn".
5. Og velg "Modul".
6. Dobbeltklikk på ny modul for å åpne redigeringsområdet.
7. Lim inn følgende makro der:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Klikk deretter "Kjør" eller trykk "F5".
9. Nå i "Bla gjennom"-vinduet, velg flere filer ved å trykke "Ctrl" og klikk "OK".
10. Deretter vil alt innhold i valgte filer bli satt sammen i det nye dokumentet, med tekster til hvert dokumenttarting på en ny side.

OBS:

Som vi nevnte, setter denne makroen teksten til hvert dokument på en ny side. Men hvis du trenger at de skal være etter hverandre, kan du endre noen kodelinjer i makroen. Bare finn linjen "If nEachSelectedFile < nTotalFiles Then", slett den og de neste seks linjene også.

Metode 2: Slå sammen alle dokumenter i en mappe til én

I tilfelle du har en mappe med filer som skal kombineres, vil denne makroen fungere vakkert.

1. Til start av, installer og kjør makro som beskrevet i metode 1.
2. Bytt deretter ut makro med denne:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Kjør makroen ved å klikke på "Kjør".
4. Deretter ser du "Bla gjennom"-vinduet åpent. Velg mappen der du lagrer alle dokumenter. Og klikk "OK".

Tilsvarende er tekstene til hvert dokumenttarts på en ny side. For å få dem til å henge sammen etter hverandre, finn og slett kodelinjen ".InsertBreak Type:=wdPageBreak".

Beskytt Word-dokumentet ditt på riktig måte

En av de beste måtene å beskytte Word-dokumentene dine på er å sikkerhetskopiere dem med jevne mellomrom. Med sikkerhetskopier i hånden trenger du aldri å frykte tap av data. Dessuten er det også lurt å få et verktøy til reparere docx hvis noen av dem skal bli skadet.

Forfatterintroduksjon:

Vera Chen er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert skadet Excel og pdf reparere programvareprodukter. For mer informasjon besøk www.datanumen. Med