2 Raske måter å finne eller slette setninger som inneholder spesifikk tekst i Word

I denne artikkelen vil vi tilby deg 2 raske måter å finne eller slette setninger som inneholder spesifikk tekst i Word.

Det er kjent for alle at vi kan bruke «Finn og erstatt»-funksjonen i Word for enkelt å finne alle forekomster av bestemte ord. Da vil vi ikke ha noe problem med å markere, erstatte eller fjerne dem. Som du ser, er målet et ord eller en frase. I dag er vi imidlertid glade for å fortelle deg makromåten for å finne eller slette setninger som inneholder bestemt tekst.

Metode 1: Finn eller slett setninger som inneholder spesifikk tekst

1. Til å begynne med, trykk "Alt + F11" for å utløse VBA-editoren i Word.
2. Opprett deretter en ny modul ved å klikke "Normal".
3. Klikk deretter "Sett inn" og velg "Modul" for å få en ny.
4. Og åpne modulen med dobbeltklikk.
5. Lim inn følgende koder:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Klikk deretter "Kjør".
7. Det vil være en inntastingsboks som ber deg skrive inn tekst. Bare skriv inn den vanlige teksten som alle setningene inneholder. Klikk "OK".
8. Deretter vil du se en setning som inneholder teksten i utvalg med en meldingsboks som spør opp. Klikk "Ja" for å slette setningen og "Nei" for å beholde den.
9. Etter bekreftelsen er neste setning med angitt tekst valgt. Og det er også bekreftelsesboksen. Makroen tar deg med til å gå gjennom hele dokumentet, finne målsetninger og spør om bekreftelse hver gang.

Metode 2: Finn eller slett setninger som inneholder tekst på en liste

Med makroen i metode 1 kan du bare søke etter ett ord eller en setning om gangen. Du kan selvfølgelig kjøre makroen gjentatte ganger for å søke etter å finne flere forekomster av ord eller setninger. For å møte behovet for flere søk, vil vi gi deg en annen makro.

1. Først legger du alle måltekstene i et nytt dokument. Sørg for at hver tekstdel opptar ett avsnitt uten mellomrom. Lukk og lagre dokumentet.
2. Neste installer og kjør en makro med de nøyaktige trinnene i metode 1.
3. Bytt deretter ut makro med denne:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Nå skal "Bla gjennom"-vinduet åpnes. Velg dokumentet som nettopp er lagret og klikk "Åpne".
5. Følgende prosedyre er den samme som i metode 1.

Tilnærming til å håndtere korrupte dokumenter

Tap av verdifull data er helt ødeleggende. Det kan til og med sette virksomheten din på spill. For å unngå slik frustrasjon må du få tak i en Ordretting verktøyet så snart som mulig. Et slikt verktøy skal hjelpe deg å vinne kampen mot dokumentkorrupsjon.

Forfatterintroduksjon:

Vera Chen er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert fikse Excel og pdf reparere programvareprodukter. For mer informasjon besøk www.datanumen. Med