2 raske måter å trekke ut individuelle sider fra Word-dokumentet ditt

I dagens innlegg vil vi dele to raske måter å trekke ut individuelle sider fra Word-dokumentet ditt på.

Noen ganger i et Word-dokument kan hver side inneholde ganske uavhengig innhold, for eksempel en tabell. Og du må sannsynligvis sende forskjellige bord til forskjellige personer. Deretter må du lagre hver tabell som er hver side, som en egen fil.

Den første ideen vi tenker bør være den klassiske kopier og lim inn. Likevel kan alt som involverer valg være irriterende noen ganger, for å dra og velge kan enkelt gjøre en slutt uten valg i det hele tatt. Av denne grunn anbefaler vi deg 2 raske metoder som bruker makro for å gjøre jobben.

Metode 1: Pakk ut gjeldende side og lagre den som et nytt dokument

1. Først og fremst, plasser markøren på siden du vil trekke ut.
2. Klikk på "Utvikler"-fanen og klikk deretter på "Visual Basic" for å starte VBA-editoren. Hvis "Utvikler" ikke er aktivert, trykker du bare "Alt+ F11" i stedet.
3. For det andre, gå til "Normal"-prosjektet ved å klikke på det.
4. Klikk deretter på "Sett inn"-fanen og velg "Modul".
5. Dobbeltklikk på den nye modulen for å åpne redigeringsområdet.
6. Deretter limer du inn følgende koder der:

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. Til slutt klikker du på "Kjør"-knappen.

Nå blir det 2 inndatabokser. Skriv inn banen der du vil lagre det nye dokumentet i den første inntastingsboksen. Og skriv inn det nye dokumentnavnet på det andre.

Metode 2: Pakk ut hver side og lagre den som et nytt dokument

Den følgende makroen lar deg trekke ut hver enkelt side i et dokument.

1. Først trykker du på "Ctrl + Hjem" for å gå helt til begynnelsen av dokumentet.
2. Følg deretter de samme trinnene i metode 1 for å installere og kjøre en makro.
3. Denne gangen bytt ut makroen med denne:

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Håndter Word-problemer

Det finnes og vil alltid finnes diverse Word-problemer. Poenget er å lære å fikse dem ordentlig. Den mest anbefalte måten er selvfølgelig å få en sofistikert Ordgjenoppretting verktøy. Du bør bruke hvert minutt for å gjenopprette dataene dine før det er for sent.

Forfatterintroduksjon:

Vera Chen er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert korrupt xlsx og pdf reparere programvareprodukter. For mer informasjon besøk www.datanumen. Med