2 Raske måter å eksportere listen over alle flaggede Outlook-e-poster til Excel

Hvis du vil eksportere listen over alle flaggede e-poster fra Outlook-postboksen til Excel, kan du bruke en av de to metodene som er delt i denne artikkelen.

For eksempel, for å håndtere alle flaggede e-poster mer betimelig eller dele dem med noen andre, kan du håpe å eksportere dem til et Excel-regneark. Her vil vi introdusere 2 tilnærminger for å realisere det. Den tidligere bruker standard "Importer og eksporter" funksjon etter å ha funnet flaggede e-poster. For å være ærlig er det litt kjedelig. Derfor vil vi i sistnevnte lære deg en mer praktisk måte som bruker VBA.

Metode 1: Eksporter alle funnet flaggede e-poster manuelt

1. Først av alt, klikk i søkeboksen over e-postlisten.
2. Klikk deretter på "Alle postelementer" i "Omfang"-gruppen på fanen "Søk".
3. Klikk deretter på "Flagget"-knappen i "Definer"-gruppen.
4. Etter alle flaggede e-poster vist i listen, velg én e-post og trykk "Ctrl + A" for å velge alle.
5. Deretter trykker du på "Ctrl + Shift + V" snarveier.
6. I den nye dialogboksen oppretter du en ny mappe under Outlook-filen.
7. Senere velger du den nye opprettede mappen og klikker "OK", som vil flytte alle funnet flaggede e-poster til den nye mappen.
8. Klikk deretter "Fil"> "Åpne"> "Importer",
9. I popup-dialogboksen velger du «Eksporter til en fil» > «Neste» > «Microsoft Excel 97-2003» > «Neste».
10. På den nye skjermen velger du riktig mappe og trykker på "Neste".
11. Følg deretter veiviserne for å fullføre "Eksporter".
12. Du vil få en ny Excel-fil, vist som følgende skjermbilde.

Metode 2: Eksporter listen over alle flaggede e-poster via VBA

1. I Outlook, trykk "Alt + F11" for å utløse VBA-editor.
2. Aktiver deretter "MS Excel Object" i henhold til "Slik legger du til en objektbibliotekreferanse i VBA".
3. Deretter kopierer du VBA-koden nedenfor til en modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Til slutt setter du markøren i "ExportAllFlaggedEmailsToExcel"-underrutinen og trykker på "F5"-tasten.
5. Velg deretter en Outlook-fil i den nye dialogboksen.
6. Når du får "Completed" prompt, vil du også få en ny Excel-fil, som bildet nedenfor.

Beskytt Outlook mot korrupsjon

Outlook er utsatt for feil og korrupsjon, og det er derfor en svært vanskelig oppgave for oss å beskytte Outlook-dataene våre. Den mest effektive og praktiske måten er utvilsomt å ta regelmessige sikkerhetskopier av data for Outlook. I tillegg til dette er det også nødvendig for oss å få tak i et kraftig og pålitelig Outlook-reparasjonsverktøy, for eksempel DataNumen Outlook Repair. Det vil komme godt med hvis verktøy for reparasjon av innboks gir ingen effekt.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert fastsette SQL Server og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med