2 metoder for raskt å sende valgte celler i et Excel-regneark som en Outlook-e-post

Noen ganger vil du kanskje raskt sette inn de valgte cellene i et Excel-regneark til en Outlook-e-post og sende ut denne e-posten. Denne artikkelen vil se på dette ønsket for å tilby deg 2 metoder.

Min forrige artikkel "2 raske metoder for å sende et Excel-regneark som en Outlook-e-post” har lært deg hvordan du sender et helt Excel-regneark som en e-post. Noen ganger ønsker du imidlertid bare å sende de valgte cellene i et regneark som en e-post. Som svar på dette kravet vil vi her avsløre deg 2 metoder. Du kan velge enten etter dine preferanser.

Metode 1: Kopier valgte celler til e-post manuelt

1. Til å begynne med, åpne kildefilen i Excel og få tilgang til riktig Excel-regneark.
2. Velg deretter cellene du vil sende som en Outlook-e-post.
3. Deretter trykker du på "Ctrl + C" snarveier for å kopiere de valgte cellene.
4. Etter det starter du Outlook-applikasjonen.
5. Deretter klikker du på "Ny e-post"-knappen i "Hjem"-båndet for å opprette en ny Outlook-e-post.
6. Senere i det nye meldingsvinduet klikker du på meldingstekstdelen.
7. Og trykk deretter "Ctrl + V" -tastene for å lime inn de tidligere kopierte valgte Excel-cellene.
8. Til slutt kan du skrive e-posten som vanlig og klikke på "Send"-knappen for å sende den ut.

Metode 2: Send valgte celler som e-post via VBA

1. Helt i begynnelsen åpner du Excel-kildearbeidsboken.
2. Trykk deretter på "Alt + F11"-tastene for å få tilgang til Excel VBA-editor.
3. I det nye vinduet klikker du på "Sett inn" > "Modul" for å sette inn en ny modul.
4. Deretter bør du aktivere Microsoft Outlook-objektet. Klikk på «Verktøy» > «Referanser». Finn og merk av for «Microsoft Outlook-objektbibliotek» i dialogboksen som dukker opp.
5. Kopier deretter følgende VBA-kode inn i denne modulen.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Til slutt kan du prøve.

• Først velger du de spesifikke cellene som vanlig.
• Gå deretter tilbake til den nye makroen og trykk F5-tasten for å utløse den.
• Med en gang vil en ny Outlook-e-post vises, der du kan se at de valgte cellene er satt inn i e-postteksten, som følgende skjermbilde:

PST-filen er samme sårbar som Excel-fil

Som vi vet, er Excel-filer og Word-dokumenter utsatt for korrupsjon. Det samme gjelder faktisk for PST-filer, som inneholder alle elementene i Outlook-postkassen din. Så det er en vanskelig oppgave å sikre PST-dataene dine. Et av de mest effektive tiltakene er å sikkerhetskopiere filen regelmessig. I tillegg, for å gi umiddelbar redning, bør du ha et erfarent verktøy klar, for eksempel DataNumen Outlook Repair, som er i stand til gjenopprette Outlook data uten å svette.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert reparere mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med