2 metoder for å slette alle kontakter uten e-postadresse i Outlook

Hvis du finner ut at noen kontakter ikke har noen e-postadresse i Outlook, kan det være lurt å behandle hver kontaktmappe for å slette alle slike kontakter. Denne post vil dele 2 midler med deg.

Kanskje du har mange kontakter i Outlook, og noen av dem har ikke e-postadresse. Hvis du tror at de ikke lenger er nyttige, må du håpe å slette alle kontaktene uten e-postadresse. På standardmåten kan du bruke "Instant Search" for å finne dem og deretter slette dem manuelt, som følgende metode 1. Likevel er det litt kjedelig. Derfor vil vi i metode 2 lære deg en annen mer effektiv måte.

Metode 1: Slett manuelt etter å ha funnet kontakter uten e-postadresse

1. For somtart, trykk på "Ctrl + 3"-tastene for å få tilgang til "Kontakter"-panelet.
2. Klikk deretter i søkeboksen.
3. Deretter, i det nye "Søk"-båndet, klikker du på "Alle kontaktelementer".
4. Deretter klikker du på "Har adresse" > "Har e-postadresse".
5. Etter det vil "IKKE e-postadresser:=[]"-kriteriet legges til i søkeboksen. Du må fjerne "NOT".
6. Deretter vil alle kontaktene uten e-postadresse bli oppført.
7. Nå bør du velge kontakter i søkeresultatene manuelt ved at kontaktgruppene dine også må være i listen.
8. Til slutt trykker du på "Del"-tasten for å slette alle de valgte kontaktene.

Metode 2: Batch-slett alle kontakter uten e-postadresse med VBA

1. Først trykker du på "Alt + F11" for å starte VBA-redigering i Outlook.
2. I det nye skjermbildet kopierer du følgende VBA-kode inn i en modul.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Senere klikker du i "BatchDeleteAllContactsWithoutEmailAddress"-underrutinen.
4. Til slutt, trykk "F5" for å utløse denne makroen.
5. Når den er fullført, vil du få en melding om resultatene, som bildet nedenfor.
6. Alle kontaktene uten e-postadresse er flyttet til mappen "Slettede elementer".

Hold deg langt unna alle potensielle risikoer

Outlook kan bli skadet på grunn av en rekke faktorer, for eksempel virus, brukerfeil, programvarefeil samt maskinvarefeil. Du må være motvillig til å oppleve Outlook-skade, så du må holde alle disse potensielle risikoene i sjakk. Du må for eksempel montere kraftig antivirusprogramvare på PC-en. I tillegg må du sikkerhetskopiere Outlook-dataene dine med jevne mellomrom. Sist, men ikke minst, bør du forberede et robust og pålitelig reparasjonsverktøy, som f.eks DataNumen Outlook Repair. Det kan fikse din korrupt PST fil med letthet.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert SQL Server korrupsjon og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med