2 raske måter å trekke ut deler fra Word-dokumentet ditt

I denne artikkelen vil vi tilby deg 2 raske og enkle måter å trekke ut deler fra Word-dokumentet til en eller flere.

Det skjer ganske ofte å trekke ut innhold fra ett dokument til et annet. Og i vår forrige artikkel har vi diskutert hvordan du trekker ut sider fra dokumentet. For detaljert informasjon kan du se denne artikkelen: 2 raske måter å trekke ut individuelle sider fra Word-dokumentet ditt

I dag vil vi vise deg hvordan du trekker ut etter seksjon.    

Metode 1: Trekk ut gjeldende seksjon til et nytt dokument

1. Først av alt, plasser markøren i en målseksjon.
2. Trykk deretter "Alt + F11" for å starte VBA-editor i Word.
3. Klikk deretter på "Normal" i venstre kolonne.
4. Og på menylinjen, klikk "Sett inn".
5. Velg deretter "Modul" på den rullegardinmenyen.
6. Dobbeltklikk for å åpne den nye modulen og lim inn følgende koder der:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Klikk deretter "Kjør" på menylinjen eller trykk "F5".
8. Da vil det dukke opp "Bla gjennom"-vinduet. Velg et sted å lagre det nye dokumentet og klikk "OK".
9. Og i "Filnavn"-boksen, skriv inn navnet på den nye filen og klikk "OK".

Nå har du trukket ut delen til et nytt dokument.

Metode 2: Trekk ut hver seksjon i dokumentet til individuelle nye

Denne måten kan hjelpe deg med å batchbehandle alle seksjoner i et dokument. Selvfølgelig trenger vi en makro også.

1. Til å begynne med, åpne måldokumentet.
2. Følg deretter trinnene i metode 1 for å installere og kjøre en makro.
3. Bare denne gangen bytt ut den makroen med denne:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Likevel, i "Bla gjennom"-vinduet, velg en lagringsbane og klikk "OK".

Rett opp irriterende ordfeil

Det er vanlig å komme over noen Word-feil mens du bruker det. Irriterende kan det være, vi må ta oss tid til det gjenopprette ordet så snart som mulig. For jo lenger vi utsetter det, jo mer alvorlig kan tapet av data bli. Derfor anbefales det å få tak i et reparasjonsverktøy på forhånd.

Forfatterintroduksjon:

Vera Chen er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert ødelagt xls og pdf reparere programvareprodukter. For mer informasjon besøk www.datanumen. Med