Outlook အီးမေးလ်ကို ရုပ်ပုံဖိုင်အဖြစ် အမြန်ထုတ်နည်း

အချို့သောအသုံးပြုသူများသည် jpg ဖိုင်ကဲ့သို့သော ရုပ်ပုံဖိုင်အဖြစ် Outlook အီးမေးလ်ကို တင်ပို့လိုကြသည်။ ထို့ကြောင့်၊ ဤဆောင်းပါးတွင်၊ Outlook VBA ကုဒ်မှတစ်ဆင့် ၎င်းကို မည်သို့ရယူရမည်ကို မိတ်ဆက်ပေးပါမည်။

အီးမေးလ်တစ်စောင်ကို စာသားဖိုင်၊ Word စာရွက်စာတမ်းစသည်ဖြင့် တင်ပို့ခြင်းအတွက် လှည့်ကွက်မျိုးစုံကို သင်လေ့လာထားရပါမည်။ ထို့နောက် JPG ဖိုင်ကဲ့သို့ ပုံကဲ့သို့ အီးမေးလ်တစ်စောင်ကို မည်ကဲ့သို့ ထုတ်ယူနိုင်မည်နည်း။ ထင်ရှားသည်မှာ၊ Outlook တွင် ဤလုပ်ဆောင်ချက် မရှိပါ။ သို့သော်၊ နောက်ပိုင်းတွင်၊ ကျွန်ုပ်တို့သည် သင့်အား အမြန်နည်းလမ်းများကို မျှဝေပါမည်။

ပုံဖိုင်အဖြစ် Outlook အီးမေးလ်ကို အမြန်ထုတ်ပါ။

1. အစပြုရန်အတွက်၊ သင်၏ Outlook application ကိုဖွင့်ပါ။
2. ထို့နောက်၊ ပင်မ Outlook ဝင်းဒိုးတွင်၊ ဆောင်းပါးနှင့်အညီ VBA တည်းဖြတ်သူထံ ဝင်ရောက်ရယူပါ - "သင်၏ Outlook တွင် VBA ကုဒ်ကိုမည်သို့ဖွင့်မည်နည်း။"။
3. ထို့နောက် “MS Word Object Library” နှင့် “MS” ကိုဖွင့်ပါ။ PowerPoint ဆောင်းပါးကို ရည်ညွှန်းခြင်းဖြင့် “Object Library”VBA မှာ Object Library Reference ထည့်နည်း"။
4. ထို့နောက်၊ အောက်ပါ VBA ကုဒ်ကို ကွက်လပ်တစ်ခုထဲသို့ ကူးယူပြီး ကူးထည့်ပါ။

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. ၎င်းနောက်၊ သင်သည် Quick Access Toolbar သို့ မက်ခရိုကို ထည့်ရန် လိုအပ်သည်။
6. ထို့နောက်တွင် သင်သည် VBA တည်းဖြတ်သူကို ပိတ်နိုင်သည်။
7. နောက်ပိုင်းတွင်၊ အီးမေးလ်တစ်စောင်ကို ရွေးချယ်ပြီး အမြန်ဝင်ရောက်ခြင်းတူးလ်ဘားရှိ မက်ခရိုခလုတ်ကို နှိပ်ပါ။
8. မက်ခရို ပြီးသွားသောအခါ၊ သင်သည် ဤအီးမေးလ်မှ ထုတ်ယူထားသော ပုံဖိုင်ကို ရှာဖွေရန် ကြိုတင်သတ်မှတ်ထားသော စက်တွင်းဖိုင်တွဲသို့ သွားနိုင်သည်။

ပျက်စီးနေသောဖိုင်မှ Outlook ဒေတာကိုရယူပါ။

သင့်ရဲ့ Outlook ဖိုင်ဟာ ပြင်းထန်တဲ့ ပျက်စီးမှုတွေ ကြုံတွေ့ရရင် အတော်လေး စိတ်ပျက်စရာ ဖြစ်နိုင်ပါတယ်။ အဲဒီလိုအခြေအနေမျိုးမှာ၊ သင်ဟာ ခိုးယူခံရတဲ့ ဖိုင်ကနေ Outlook data တွေကို ဆက်လက်ထုတ်ယူရပါလိမ့်မယ်။ အသုံးပြုသူတချို့ဟာ inbox repair tool ကို အသုံးပြုလေ့ရှိပါတယ်။ ဒါပေမယ့် အများစုမှာတော့ အကျိုးသက်ရောက်မှု မရှိပါဘူး။ ဒါကြောင့် သင်ဟာ ခိုင်မာပြီး ယုံကြည်စိတ်ချရတဲ့ ဖိုင်တစ်ခုကို သိမ်းဆည်းထားသင့်ပါတယ်။ PST ပြင်ဆင်ခြင်း။ အစရှိတဲ့ tool တွေ၊ DataNumen Outlook Repair. ၎င်းသည် ပျက်စီးနေသောဖိုင်ကို စကင်န်ဖတ်ကာ ရှုပ်ထွေးမှုမရှိဘဲ အများဆုံးဒေတာကို ပြန်လည်ရယူနိုင်သည်။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ mdf ပြင်ဆင်ခြင်း။ နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com