Word Document တစ်ခု၏ တိကျသော စာမျက်နှာများကို Outlook အီးမေးလ်သို့ မည်ကဲ့သို့ လျင်မြန်စွာ တွဲတင်နည်း

MS Word တွင် လက်ရှိ Word စာရွက်စာတမ်းကို အီးမေးလ် ပူးတွဲပါဖိုင်အဖြစ် ပေးပို့ရန် အသုံးပြုသူများအား တိုက်ရိုက် ပံ့ပိုးပေးသည့် အင်္ဂါရပ်တစ်ခု ရှိသည်။ သို့သော် တစ်ခါတစ်ရံတွင်၊ သင်သည် Word document တစ်ခု၏ သီးခြားစာမျက်နှာများကို Outlook အီးမေးလ်တစ်ခုသို့ ပူးတွဲထားရန်သာ မျှော်လင့်နိုင်သည်။ အခု ဒီဆောင်းပါးက မင်းကို နည်းလမ်းတစ်ခု မျှဝေပေးလိမ့်မယ်။

MS Word အပလီကေးရှင်းတွင် အီးမေးလ် ပူးတွဲပါဖိုင်အဖြစ် Word စာရွက်စာတမ်းတစ်ခုလုံးကို ပေးပို့ရန်၊ သင်သည် "ဖိုင်" မီနူးသို့ ရိုးရှင်းစွာသွားပြီး "သိမ်းဆည်းခြင်းနှင့် ပေးပို့ခြင်း" တက်ဘ်သို့ ပြောင်းနိုင်သည်၊ ၎င်းအောက်ရှိ "ပေးပို့မှုအဖြစ် ပူးတွဲပေးပို့ခြင်း" ခလုတ်ကို သင်တွေ့နိုင်သည်။ သို့တိုင်၊ တစ်ခါတစ်ရံတွင် သင်ပေးပို့လိုသောအရာသည် စာရွက်စာတမ်း၏ သီးခြားစာမျက်နှာများသာ ဖြစ်နိုင်ပါသည်။ ဤအခြေအနေတွင်၊ သင်သည် ၎င်းကိုပြီးမြောက်စေရန် အောက်ပါတို့တွင် မိတ်ဆက်ထားသော နည်းလမ်းကို အသုံးပြုနိုင်သည်။

Word Document တစ်ခု၏ တိကျသော စာမျက်နှာများကို အီးမေးလ်တစ်ခုသို့ ပူးတွဲပါ။

1. ပထမဦးစွာ၊ သင်သည် အီးမေးလ်သို့ ပေးပို့လိုသော သီးခြားစာမျက်နှာများ၏ အရင်းအမြစ် Word စာရွက်စာတမ်းကို ဖွင့်သင့်သည်။
2. ထို့နောက် MS Word ဝင်းဒိုးသို့ရောက်ပြီးနောက်၊ သင်သည် “Alt + F11” ခလုတ်များကို နှိပ်ရန် လိုအပ်သည်။
3. ထို့နောက် သင်သည် MS Word ရှိ VBA တည်းဖြတ်သူထံ ဝင်ရောက်ခွင့်ရရှိမည်ဖြစ်သည်။
4. ပြီးရင် “Microsoft Outlook Object Library” ကို enable လုပ်ရပါမယ်။ “Tools” > “Reference” ကို နှိပ်ပြီး enable လုပ်နိုင်ပါတယ်။
5. ထို့နောက်တွင်၊ သင်သည် အောက်ပါ VBA ကုဒ်ကို အသုံးမပြုသော module တစ်ခုသို့ ကူးယူသင့်သည်။

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. နောက်ဆုံးတွင် သင်သည် ဤ macro ကို run နိုင်သည်။ F5 ခလုတ်ကို နှိပ်ရုံသာ သို့မဟုတ် ကိရိယာဘားရှိ “Run” သင်္ကေတကို နှိပ်ပါ။
7. Macro ပြီးပါက အောက်ပါ screenshot ကဲ့သို့ source Word document ၏ ကောက်နုတ်ချက်နှင့်အတူ ပူးတွဲပါရှိသော Outlook အီးမေးလ်အသစ်ကို ပြသပါမည်။

ပျက်စီးနေသော Outlook ဖိုင်မှ အများဆုံးဒေတာကို ထုတ်ယူပါ။

အကယ်၍ သင်သည် Outlook ကို ဆယ်စုနှစ်များစွာ အသုံးပြုခဲ့လျှင် ပေါ့ပ်အပ်အတွင်းပိုင်းအမှားမက်ဆေ့ချ်များ၊ ရုတ်တရတ်ပျက်ကျမှုများအပြင် ပြင်းထန်သောဖိုင်ပျက်စီးမှုများအပါအဝင် Outlook ပြဿနာများနှင့် ရင်ဆိုင်ရနိုင်သည်။ အဆိုပါအချက်ကြောင့်ဖြစ်သည်။ scanpstတပ်ဆင်ထားသော ပြုပြင်ရေးကိရိယာသည် ပြဿနာအသေးအမွှားများကိုသာ ကိုင်တွယ်ဖြေရှင်းနိုင်သည်၊ သင်သည် ပြင်ပအားကောင်းသော ပြုပြင်ရေးကိရိယာကို နေရာလေးတွင် ထားရှိရန် ပိုကောင်းသည်ဟု ပြောပါ။ DataNumen Outlook Repair. ပျက်စီးနေသော Outlook ဒေတာဖိုင်မှ အများဆုံးဒေတာကို ထုတ်ယူနိုင်သည်။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ sql fix နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com