Outlook VBA မှတဆင့် တိကျသောရက်စွဲအကွာအဝေးတွင် အလုပ်များသည့်နေရာအားလုံး၏စာရင်းကို မည်သို့ပရင့်ထုတ်မည်နည်း။

Outlook ဖြေရှင်းချက် စက်တင်ဘာလ 29, 2025
ယခုမျှဝေပါ-

ဤဆောင်းပါးသည် သင့်အား "အလုပ်များနေသည်" ဟုပြထားသည့် တိကျသောရက်အပိုင်းအခြားတစ်ခုတွင် စီစဉ်ထားသည့် ချိန်းဆိုမှုများစာရင်းကို ပရင့်ထုတ်ရန် လွယ်ကူသောနည်းလမ်းကို သင်ပေးပါမည်။

သတ်မှတ်ထားတဲ့ ရက်စွဲအပိုင်းအခြားအတွင်းမှာ အလုပ်များနေတဲ့ ချိန်းဆိုမှုအားလုံးကို ရှာဖွေဖို့ ပြက္ခဒိန်အားလုံးကို ထပ်ခါတလဲလဲ လုပ်ဆောင်ဖို့ အတော်လေး လွယ်ကူပါတယ်။ ရှာဖွေရေး scope ကို "All Calendar Items" လို့ သတ်မှတ်လိုက်ရုံပါပဲ။ ပြီးရင် "Show Time As" ကို "Busy" နဲ့ ညီမျှတဲ့ ချိန်းဆိုမှုတွေကို သတ်မှတ်ထားတဲ့ စတင်ရက်နဲ့ ပြီးဆုံးရက်အတွင်းမှာ ရှာဖွေပါ။ ဒါပေမယ့် ဒီနည်းနဲ့ ရှာတွေ့ထားတဲ့ ချိန်းဆိုမှုတွေကို ပရင့်ထုတ်ဖို့ ရည်ရွယ်ပြီး "File" > "Print" ကို သွားတဲ့အခါ "Memo Style" ပဲ ရနိုင်တာကို တွေ့ရပါလိမ့်မယ်။ ဆိုလိုတာက ရှာတွေ့ထားတဲ့ ချိန်းဆိုမှုတွေကို စာရင်းထဲမှာ ပရင့်ထုတ်လို့ မရပါဘူး။ ဒါကြောင့် အဲဒီလို ချိန်းဆိုမှုတွေရဲ့ စာရင်းကို ပရင့်ထုတ်ချင်ရင် အောက်ပါနည်းလမ်းကို အသုံးပြုနိုင်ပါတယ်။

တွေ့ရှိသောချိန်းဆိုမှုများအတွက်သာ Memo ပုံစံကို ရရှိနိုင်သည်။

တိကျသောရက်စွဲအပိုင်းအခြားတစ်ခုတွင် အလုပ်များသော ချိန်းဆိုမှုအားလုံး၏စာရင်းကို ပရင့်ထုတ်ပါ။

  1. အစပိုင်းတွင်၊ "Alt + F11" မှတစ်ဆင့် Outlook VBA တည်းဖြတ်မှုကို စတင်ပါ။
  2. ထို့နောက် “Microsoft Visual Basic for Applications” ပေါ်လာသည့် ဝင်းဒိုးတွင် “MS Excel Object Library” ကို ရည်ညွှန်းချက်အဖြစ် ထည့်ပါ။VBA မှာ Object Library Reference ထည့်နည်း"။
  3. ထို့နောက်တွင်၊ အောက်ပါ VBA ကုဒ်ကို module တစ်ခုတွင်ထည့်ပါ။
Dim dStart, dEnd As Date
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub PrintListOfAllBusyAppointments()
    Dim objStore As Store
    Dim objFolder As Folder
 
    dStart = InputBox("Enter the start date:", , Date)
    dEnd = InputBox("Enter the end date:", , Date + 30)
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
 
    With objExcelWorksheet
         .Cells(1, 1) = "Subject"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 2) = "Location"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 3) = "Start"
         .Cells(1, 3).Font.Bold = True
         .Cells(1, 4) = "End"
         .Cells(1, 4).Font.Bold = True
         .Cells(1, 5) = "In Folder"
         .Cells(1, 5).Font.Bold = True
    End With
 
    For Each objStore In Application.Session.Stores
        For Each objFolder In objStore.GetRootFolder.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
 
    objExcelWorksheet.Columns("A:E").AutoFit
    objExcelWorksheet.PrintOut
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

Sub ProcessFolders(ByVal objCurFolder As Folder)
    Dim strFilter As String
    Dim objItems As Outlook.Items
    Dim objRestrictedItems As Outlook.Items
    Dim objAppointment As AppointmentItem
    Dim nLastRow As Integer
    Dim objSubFolder As Folder
 
    Set objItems = objCurFolder.Items
    objItems.IncludeRecurrences = True
    objItems.Sort "[Start]"
 
    'Get the appointments in the specific date range
    strFilter = "[Start] >= " & Chr(34) & dStart & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEnd & " 11:59 PM" & Chr(34)
    Set objRestrictedItems = objItems.Restrict(strFilter)

    For Each objAppointment In objRestrictedItems
        If objAppointment.BusyStatus = olBusy Then
           nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
           With objExcelWorksheet
                .Range("A" & nLastRow) = objAppointment.Subject
                .Range("B" & nLastRow) = objAppointment.Location
                .Range("C" & nLastRow) = objAppointment.Start
                .Range("D" & nLastRow) = objAppointment.End
                .Range("E" & nLastRow) = objCurFolder.FolderPath
           End With
        End If
    Next

    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubFolder In objCurFolder.Folders
           Call ProcessFolders(objSubFolder)
       Next
    End If
End Sub

VBA ကုဒ် - တိကျသောရက်စွဲအပိုင်းအခြားတစ်ခုတွင် အလုပ်များသော ချိန်းဆိုမှုများအားလုံးကို ပရင့်ထုတ်ပါ။

  1. နောက်ပိုင်းတွင်၊ ပထမလုပ်ရိုးလုပ်စဉ်ခွဲသို့ နှိပ်ပြီး “F5” ခလုတ်ခလုတ်ကို နှိပ်ပါ။
  2. ထို့နောက် ချိန်းဆိုမှုများကို ရှာဖွေရန် ရက်အပိုင်းအခြားကို သတ်မှတ်ရန် လိုအပ်ပါသည်။ရက်စွဲအပိုင်းကို သတ်မှတ်ပါ။
  3. ထို့နောက် မက်ခရိုကို ဆက်လက်လုပ်ဆောင်ရန် “OK” ကိုနှိပ်ပါ။
  4. နောက်ဆုံးတွင်၊ မက်ခရိုပြီးသောအခါ၊ ပြက္ခဒိန်ဖိုင်တွဲများအားလုံးရှိ ကြိုတင်သတ်မှတ်ထားသော ရက်အပိုင်းအခြားရှိ အလုပ်များသည့်ရက်စွဲများစာရင်းကို အောက်ပါဖန်သားပြင်ဓာတ်ပုံတွင် ပြထားသည့်အတိုင်း ရိုက်နှိပ်မည်ဖြစ်သည်။သတ်မှတ်ထားသော ရက်အပိုင်းအခြားအတွင်း အလုပ်များသော ချိန်းဆိုမှုအားလုံး၏ စာရင်းကို ရိုက်နှိပ်ထားသည်။

အနှောင့်အယှက်ဖြစ်စေသော Outlook အကျင့်ပျက်ခြစားမှုကို ဖြေရှင်းပါ။

သင့် Outlook ကို အမြဲတမ်း မလျော်ကန်သော ပုံစံဖြင့် ပိတ်ပါက၊ နောက်ပိုင်းတွင် ပြဿနာများစွာ ကြုံတွေ့ရနိုင်သည်။ ၎င်းတို့အနက် Outlook ဖိုင် ပျက်စီးသွားခြင်းသည် အဆိုးဆုံးဖြစ်သည်။ သင့်ဒေတာကို မဆုံးရှုံးလိုပါက၊ ကဲ့သို့သော PST fix tool ကို အသုံးပြုရန်လိုအပ်ပါသည်။ DataNumen Outlook Repair. ၎င်းသည် အများဆုံးဒေတာကို ပြန်လည်ရယူနိုင်သည်။ ပျက်စီးနေသော Outlook ဖိုင်။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ sql fix နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com

ယခုမျှဝေပါ-

မှတ်ချက်များကိုပိတ်ထားကြသည်။