သင်၏ Outlook အဆက်အသွယ်များမှ တိကျသော Domain တစ်ခုဖြင့် အီးမေးလ်လိပ်စာများအားလုံးကို အစုလိုက်ဖယ်ရှားနည်း

Outlook ဖြေရှင်းချက် စက်တင်ဘာလ 29, 2025

တစ်ခါတစ်ရံတွင်၊ သင့်အဆက်အသွယ်များမှ သီးသန့်ဒိုမိန်းတစ်ခုပါရှိသော အီးမေးလ်လိပ်စာအားလုံးကို ဖယ်ရှားရန် မျှော်လင့်နိုင်သည်။ ဒီလိုအခြေအနေမျိုးမှာ တစ်ယောက်ပြီးတစ်ယောက် လုပ်ချင်တိုင်းလုပ်ချင်စိတ်မရှိကြဘူး။ ထို့ကြောင့် ဤပစ္စယောost ပိုထက်မြက်တဲ့ နည်းလမ်းကို သင်ပေးပါလိမ့်မယ်။

ဥပမာအားဖြင့် ကုမ္ပဏီတစ်ခုသည် ၎င်း၏အမည်ကို ပြောင်းလဲသည်။ တစ်ချိန်တည်းမှာပင် ကုမ္ပဏီ၏ ဒိုမိန်းသည်လည်း ပြောင်းလဲလာသည်။ သို့ရာတွင်၊ Outlook တွင်၊ သင်သည် ဤကုမ္ပဏီတွင် အဆက်အသွယ်များစွာကို သိမ်းဆည်းထားပြီး၊ ၎င်း၏ အီးမေးလ်လိပ်စာများသည် ဒိုမိန်းဟောင်းနှင့် ရှိနေသည်။ ဟုတ်ပါတယ်၊ ဤအီးမေးလ်လိပ်စာများသည် တရားဝင်တော့မည်မဟုတ်ပါ။ ထို့ကြောင့် ဤအခြေအနေအောက်တွင် သင်သည် ဤအီးမေးလ်လိပ်စာများကို တစ်ချက်တည်း ဖယ်ရှားလိုပါက အောက်ပါနည်းလမ်းကို အသုံးပြုနိုင်ပါသည်။

သီးခြား Domain တစ်ခုပါရှိသော အီးမေးလ်လိပ်စာများအားလုံးကို အဆက်အသွယ်များမှ ဖယ်ရှားပါ။

အဖြစ်အတွက်tart၊ သော့ဖြတ်လမ်း – “Alt + F11” ဖြင့် Outlook VBA တည်းဖြတ်သူကို ဝင်ရောက်ပါ။
ထို့နောက် ဝင်းဒိုးအသစ်တွင်၊ အောက်ဖော်ပြပါ VBA ကုဒ်ကို အလွတ် module တစ်ခုတွင် ထားလိုက်ပါ။

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

ထို့နောက်၊ "BatchRemoveAllEmailAddressesInSpecificDomain" တွင် cursor ကိုထည့်ပါ။
နောက်ဆုံးတွင်၊ ဤ macro ကိုစတင်ရန် "F5" ခလုတ်ကိုနှိပ်ပါ။
ပြီးနောက်၊ ပေါ့ပ်အပ်ဒိုင်ယာလော့ဘောက်စ်တွင် သီးခြားဒိုမိန်းကို ထည့်သွင်းပါ။
"OK" ကိုနှိပ်ပြီးနောက်၊ Macro လည်ပတ်လိမ့်မည်။
ပြီးသွားသောအခါတွင် ရလဒ်များအကြောင်း မက်ဆေ့ချ်တစ်ခုရလိမ့်မည်။
ယခု သင်သည် အဆက်အသွယ်များကို စစ်ဆေးနိုင်သည်။ သီးခြားဒိုမိန်းပါရှိသော အီးမေးလ်လိပ်စာများအားလုံး ပျောက်ကွယ်သွားရပါမည်။

သင်၏ Outlook ဖိုင်ကို ထိန်းသိမ်းပါ။

သင့် Outlook ဝန်းကျင်တွင် အန္တရာယ်များ ပိုများလာသဖြင့်၊ သင်၏ အဖိုးတန် Outlook ဒေတာကို ကာကွယ်ရန် ပိုမိုခက်ခဲလာသည်။ ဥပမာအားဖြင့်၊ သင်သည် ပုံမှန်ဒေတာအရန်သိမ်းဆည်းမှုများတွင် ဆက်လက်ရှိနေသင့်ရုံသာမက သင်၏လုပ်ဆောင်မှုများကိုလည်း သတိထားရမည်ဖြစ်သည်။ အမည်မသိပေးပို့သူများထံမှ မည်သည့်အီးမေးလ်များကိုမဆို အလွယ်တကူယုံကြည်ခြင်းသည် ပညာမတတ်ပါ။ မဟုတ်ပါက၊ ၎င်းသည် virus သယ်ဆောင်လာပါက၊ သင်၏ Outlook ဖိုင်သည် ကူးစက်သွားမည်ဖြစ်သည်။ အဲဒီတုန်းက ကြိုးစားရမယ်။ Outlook ပြုပြင်ခြင်း ကဲ့သို့သောထူးခြားသော fix tool မှတဆင့် DataNumen Outlook Repair.

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ recover Sql Server နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com

မှတ်ချက်များကိုပိတ်ထားကြသည်။